perl/DXCommandmode.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the user facing command mode for a dx cluster
   4 #
   5 # Copyright (c) 1998 Dirk Koopman G1TLH
   6 #
   7 # $Id$
   8 #
   9
  10 package DXCommandmode;
  11
  12 @ISA = qw(DXChannel);
  13
  14 use DXUtil;
  15 use DXChannel;
  16 use DXUser;
  17 use DXVars;
  18 use DXDebug;
  19 use DXM;
  20 use DXLog;
  21 use DXLogPrint;
  22 use DXBearing;
  23 use CmdAlias;
  24 use FileHandle;
  25 use Carp;
  26
  27 use strict;
  28 use vars qw(%Cache %cmd_cache $errstr %aliases);
  29
  30 %Cache = ();                                    # cache of dynamically loaded routine's mod times
  31 %cmd_cache = ();                                # cache of short names
  32 $errstr = ();                                   # error string from eval
  33 %aliases = ();                                  # aliases for (parts of) commands
  34
  35 #
  36 # obtain a new connection this is derived from dxchannel
  37 #
  38
  39 sub new
  40 {
  41         my $self = DXChannel::alloc(@_);
  42         $self->{'sort'} = 'U';          # in absence of how to find out what sort of an object I am
  43         return $self;
  44 }
  45
  46 # this is how a a connection starts, you get a hello message and the motd with
  47 # possibly some other messages asking you to set various things up if you are
  48 # new (or nearly new and slacking) user.
  49
  50 sub start
  51 {
  52         my ($self, $line, $sort) = @_;
  53         my $user = $self->{user};
  54         my $call = $self->{call};
  55         my $name = $user->{name};
  56
  57         $self->{name} = $name ? $name : $call;
  58         $self->send($self->msg('l2',$self->{name}));
  59         $self->send_file($main::motd) if (-e $main::motd);
  60         $self->state('prompt');         # a bit of room for further expansion, passwords etc
  61         $self->{priv} = $user->priv;
  62         $self->{lang} = $user->lang;
  63         $self->{pagelth} = 20;
  64         $self->{priv} = 0 if $line =~ /^(ax|te)/; # set the connection priv to 0 - can be upgraded later
  65         $self->{consort} = $line;       # save the connection type
  66
  67         # set some necessary flags on the user if they are connecting
  68         $self->{beep} = $self->{wwv} = $self->{talk} = $self->{ann} = $self->{here} = $self->{dx} = 1;
  69         #  $self->prompt() if $self->{state} =~ /^prompt/o;
  70
  71         # add yourself to the database
  72         my $node = DXNode->get($main::mycall) or die "$main::mycall not allocated in DXNode database";
  73         my $cuser = DXNodeuser->new($self, $node, $call, 0, 1);
  74         $node->dxchan($self) if $call eq $main::myalias; # send all output for mycall to myalias
  75
  76         # issue a pc16 to everybody interested
  77         my $nchan = DXChannel->get($main::mycall);
  78         my @pc16 = DXProt::pc16($nchan, $cuser);
  79         DXProt::broadcast_ak1a(@pc16);
  80         Log('DXCommand', "$call connected");
  81
  82         # send prompts and things
  83         my $info = DXCluster::cluster();
  84         $self->send("Cluster:$info");
  85         $self->send($self->msg('namee1')) if !$user->name;
  86         $self->send($self->msg('qthe1')) if !$user->qth;
  87         $self->send($self->msg('qll')) if !$user->qra || (!$user->lat && !$user->long);
  88         $self->send($self->msg('hnodee1')) if !$user->qth;
  89
  90
  91         $self->send($self->msg('pr', $call));
  92 }
  93
  94 #
  95 # This is the normal command prompt driver
  96 #
  97
  98 sub normal
  99 {
 100         my $self = shift;
 101         my $cmdline = shift;
 102         my @ans;
 103
 104         # remove leading and trailing spaces
 105         $cmdline =~ s/^\s*(.*)\s*$/$1/;
 106
 107         if ($self->{state} eq 'page') {
 108                 my $i = $self->{pagelth};
 109                 my $ref = $self->{pagedata};
 110                 my $tot = @$ref;
 111
 112                 # abort if we get a line starting in with a
 113                 if ($cmdline =~ /^a/io) {
 114                         undef $ref;
 115                         $i = 0;
 116                 }
 117
 118                 # send a tranche of data
 119                 while ($i-- > 0 && @$ref) {
 120                         my $line = shift @$ref;
 121                         $line =~ s/\s+$//o;     # why am having to do this?
 122                         $self->send($line);
 123                 }
 124
 125                 # reset state if none or else chuck out an intermediate prompt
 126                 if ($ref && @$ref) {
 127                         $tot -= $self->{pagelth};
 128                         $self->send($self->msg('page', $tot));
 129                 } else {
 130                         $self->state('prompt');
 131                 }
 132         } else {
 133                 @ans = run_cmd($self, $cmdline) if length $cmdline;
 134
 135                 if ($self->{pagelth} && @ans > $self->{pagelth}) {
 136                         my $i;
 137                         for ($i = $self->{pagelth}; $i-- > 0; ) {
 138                                 my $line = shift @ans;
 139                                 $line =~ s/\s+$//o;     # why am having to do this?
 140                                 $self->send($line);
 141                         }
 142                         $self->{pagedata} =  \@ans;
 143                         $self->state('page');
 144                         $self->send($self->msg('page', scalar @ans));
 145                 } else {
 146                         for (@ans) {
 147                                 s/\s+$//o;              # why ?????????
 148                                 $self->send($_);
 149                         }
 150                 }
 151         }
 152
 153         # send a prompt only if we are in a prompt state
 154         $self->prompt() if $self->{state} =~ /^prompt/o;
 155 }
 156
 157 #
 158 # this is the thing that runs the command, it is done like this for the
 159 # benefit of remote command execution
 160 #
 161
 162 sub run_cmd
 163 {
 164         my $self = shift;
 165         my $user = $self->{user};
 166         my $call = $self->{call};
 167         my $cmdline = shift;
 168         my @ans;
 169
 170         if ($self->{func}) {
 171                 my $c = qq{ \@ans = $self->{func}(\$self, \$cmdline) };
 172                 dbg('eval', "stored func cmd = $c\n");
 173                 eval  $c;
 174                 if ($@) {
 175                         return (1, "Syserr: Eval err $errstr on stored func $self->{func}");
 176                 }
 177         } else {
 178
 179                 # strip out //
 180                 $cmdline =~ s|//|/|og;
 181
 182                 # split the command line up into parts, the first part is the command
 183                 my ($cmd, $args) = $cmdline =~ /^([\S\/]+)\s*(.*)/o;
 184
 185                 if ($cmd) {
 186
 187                         my ($path, $fcmd);
 188
 189                         dbg('command', "cmd: $cmd");
 190
 191                         # alias it if possible
 192                         my $acmd = CmdAlias::get_cmd($cmd);
 193                         if ($acmd) {
 194                                 ($cmd, $args) = "$acmd $args" =~ /^([\w\/]+)\s*(.*)/o;
 195                                 dbg('command', "aliased cmd: $cmd $args");
 196                         }
 197
 198                         # first expand out the entry to a command
 199                         ($path, $fcmd) = search($main::localcmd, $cmd, "pl");
 200                         ($path, $fcmd) = search($main::cmd, $cmd, "pl") if !$path || !$fcmd;
 201
 202                         if ($path && $cmd) {
 203                                 dbg('command', "path: $cmd cmd: $fcmd");
 204
 205                                 my $package = find_cmd_name($path, $fcmd);
 206                                 @ans = (0) if !$package ;
 207
 208                                 if ($package) {
 209                                         dbg('command', "package: $package");
 210
 211                                         my $c = qq{ \@ans = $package(\$self, \$args) };
 212                                         dbg('eval', "cluster cmd = $c\n");
 213                                         eval  $c;
 214                                         if ($@) {
 215                                                 @ans = (0, "Syserr: Eval err cached $package\n$@");
 216                                         }
 217                                 }
 218                         } else {
 219                                 dbg('command', "cmd: $cmd not found");
 220                                 @ans = (0);
 221                         }
 222                 }
 223         }
 224
 225         if ($ans[0]) {
 226                 shift @ans;
 227         } else {
 228                 shift @ans;
 229                 if (@ans > 0) {
 230                         unshift @ans, $self->msg('e2');
 231                 } else {
 232                         @ans = $self->msg('e1');
 233                 }
 234         }
 235         return (@ans);
 236 }
 237
 238 #
 239 # This is called from inside the main cluster processing loop and is used
 240 # for despatching commands that are doing some long processing job
 241 #
 242 sub process
 243 {
 244         my $t = time;
 245         my @dxchan = DXChannel->get_all();
 246         my $dxchan;
 247
 248         foreach $dxchan (@dxchan) {
 249                 next if $dxchan->sort ne 'U';
 250
 251                 # send a prompt if no activity out on this channel
 252                 if ($t >= $dxchan->t + $main::user_interval) {
 253                         $dxchan->prompt() if $dxchan->{state} =~ /^prompt/o;
 254                         $dxchan->t($t);
 255                 }
 256         }
 257 }
 258
 259 #
 260 # finish up a user context
 261 #
 262 sub finish
 263 {
 264         my $self = shift;
 265         my $call = $self->call;
 266
 267         # log out text
 268         if (-e "$main::data/logout") {
 269                 open(I, "$main::data/logout") or confess;
 270                 my @in = <I>;
 271                 close(I);
 272                 $self->send_now('D', @in);
 273                 sleep(1);
 274         }
 275
 276         if ($call eq $main::myalias) { # unset the channel if it is us really
 277                 my $node = DXNode->get($main::mycall);
 278                 $node->{dxchan} = 0;
 279         }
 280         my $ref = DXCluster->get_exact($call);
 281
 282         # issue a pc17 to everybody interested
 283         my $nchan = DXChannel->get($main::mycall);
 284         my $pc17 = $nchan->pc17($self);
 285         DXProt::broadcast_ak1a($pc17);
 286
 287         Log('DXCommand', "$call disconnected");
 288         $ref->del() if $ref;
 289 }
 290
 291 #
 292 # short cut to output a prompt
 293 #
 294
 295 sub prompt
 296 {
 297         my $self = shift;
 298         $self->send($self->msg($self->here ? 'pr' : 'pr2', $self->call));
 299 }
 300
 301 # broadcast a message to all users [except those mentioned after buffer]
 302 sub broadcast
 303 {
 304         my $pkg = shift;                        # ignored
 305         my $s = shift;                          # the line to be rebroadcast
 306         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 307         my @list = DXChannel->get_all(); # just in case we are called from some funny object
 308         my ($dxchan, $except);
 309
 310  L: foreach $dxchan (@list) {
 311                 next if !$dxchan->sort eq 'U'; # only interested in user channels
 312                 foreach $except (@except) {
 313                         next L if $except == $dxchan;   # ignore channels in the 'except' list
 314                 }
 315                 $dxchan->send($s);                      # send it
 316         }
 317 }
 318
 319 # gimme all the users
 320 sub get_all
 321 {
 322         my @list = DXChannel->get_all();
 323         my $ref;
 324         my @out;
 325         foreach $ref (@list) {
 326                 push @out, $ref if $ref->sort eq 'U';
 327         }
 328         return @out;
 329 }
 330
 331 #
 332 # search for the command in the cache of short->long form commands
 333 #
 334
 335 sub search
 336 {
 337         my ($path, $short_cmd, $suffix) = @_;
 338         my ($apath, $acmd);
 339
 340         # commands are lower case
 341         $short_cmd = lc $short_cmd;
 342         dbg('command', "command: $path $short_cmd\n");
 343
 344         # do some checking for funny characters
 345         return () if $short_cmd =~ /\/$/;
 346
 347         # return immediately if we have it
 348         ($apath, $acmd) = split ',', $cmd_cache{$short_cmd} if $cmd_cache{$short_cmd};
 349         if ($apath && $acmd) {
 350                 dbg('command', "cached $short_cmd = ($apath, $acmd)\n");
 351                 return ($apath, $acmd);
 352         }
 353
 354         # if not guess
 355         my @parts = split '/', $short_cmd;
 356         my $dirfn;
 357         my $curdir = $path;
 358         my $p;
 359         my $i;
 360         my @lparts;
 361
 362         for ($i = 0; $i < @parts; $i++) {
 363                 my  $p = $parts[$i];
 364                 opendir(D, $curdir) or confess "can't open $curdir $!";
 365                 my @ls = readdir D;
 366                 closedir D;
 367                 my $l;
 368                 foreach $l (sort @ls) {
 369                         next if $l =~ /^\./;
 370                         if ($i < $#parts) {             # we are dealing with directories
 371                                 if ((-d "$curdir/$l") && $p eq substr($l, 0, length $p)) {
 372                                         dbg('command', "got dir: $curdir/$l\n");
 373                                         $dirfn .= "$l/";
 374                                         $curdir .= "/$l";
 375                                         last;
 376                                 }
 377                         } else {                        # we are dealing with commands
 378                                 @lparts = split /\./, $l;
 379                                 next if $lparts[$#lparts] ne $suffix;        # only look for .$suffix files
 380                                 if ($p eq substr($l, 0, length $p)) {
 381                                         pop @lparts; #  remove the suffix
 382                                         $l = join '.', @lparts;
 383                                         #                 chop $dirfn;               # remove trailing /
 384                                         $dirfn = "" unless $dirfn;
 385                                         $cmd_cache{"$short_cmd"} = join(',', ($path, "$dirfn$l")); # cache it
 386                                         dbg('command', "got path: $path cmd: $dirfn$l\n");
 387                                         return ($path, "$dirfn$l");
 388                                 }
 389                         }
 390                 }
 391         }
 392         return ();
 393 }
 394
 395 # clear the command name cache
 396 sub clear_cmd_cache
 397 {
 398         %cmd_cache = ();
 399 }
 400
 401 #
 402 # the persistant execution of things from the command directories
 403 #
 404 #
 405 # This allows perl programs to call functions dynamically
 406 #
 407 # This has been nicked directly from the perlembed pages
 408 #
 409
 410 #require Devel::Symdump;
 411
 412 sub valid_package_name {
 413         my($string) = @_;
 414         $string =~ s/([^A-Za-z0-9\/])/sprintf("_%2x",unpack("C",$1))/eg;
 415
 416         #second pass only for words starting with a digit
 417         $string =~ s|/(\d)|sprintf("/_%2x",unpack("C",$1))|eg;
 418
 419         #Dress it up as a real package name
 420         $string =~ s/\//_/og;
 421         return "Emb_" . $string;
 422 }
 423
 424 #borrowed from Safe.pm
 425 sub delete_package {
 426         my $pkg = shift;
 427         my ($stem, $leaf);
 428
 429         no strict 'refs';
 430         $pkg = "DXCommandmode::$pkg\::"; # expand to full symbol table name
 431         ($stem, $leaf) = $pkg =~ m/(.*::)(\w+::)$/;
 432
 433         if ($stem && $leaf) {
 434                 my $stem_symtab = *{$stem}{HASH};
 435                 delete $stem_symtab->{$leaf};
 436         }
 437 }
 438
 439 # find a cmd reference
 440 # this is really for use in user written stubs
 441 #
 442 # use the result as a symbolic reference:-
 443 #
 444 # no strict 'refs';
 445 # @out = &$r($self, $line);
 446 #
 447 sub find_cmd_ref
 448 {
 449         my $cmd = shift;
 450         my $r;
 451
 452         if ($cmd) {
 453
 454                 # first expand out the entry to a command
 455                 my ($path, $fcmd) = search($main::localcmd, $cmd, "pl");
 456                 ($path, $fcmd) = search($main::cmd, $cmd, "pl") if !$path || !$fcmd;
 457
 458                 # make sure it is loaded
 459                 $r = find_cmd_name($path, $fcmd);
 460         }
 461         return $r;
 462 }
 463
 464 #
 465 # this bit of magic finds a command in the offered directory
 466 sub find_cmd_name {
 467         my $path = shift;
 468         my $cmdname = shift;
 469         my $package = valid_package_name($cmdname);
 470         my $filename = "$path/$cmdname.pl";
 471         my $mtime = -M $filename;
 472
 473         # return if we can't find it
 474         $errstr = undef;
 475         unless (defined $mtime) {
 476                 $errstr = DXM::msg('e1');
 477                 return undef;
 478         }
 479
 480         if(defined $Cache{$package}{mtime} && $Cache{$package}{mtime } <= $mtime) {
 481                 #we have compiled this subroutine already,
 482                 #it has not been updated on disk, nothing left to do
 483                 #print STDERR "already compiled $package->handler\n";
 484                 ;
 485         } else {
 486                 delete_package($package) if defined $Cache{$package}{mtime};
 487
 488                 my $fh = new FileHandle;
 489                 if (!open $fh, $filename) {
 490                         $errstr = "Syserr: can't open '$filename' $!";
 491                         return undef;
 492                 };
 493                 local $/ = undef;
 494                 my $sub = <$fh>;
 495                 close $fh;
 496
 497                 #wrap the code into a subroutine inside our unique package
 498                 my $eval = qq{ sub $package { $sub } };
 499
 500                 if (isdbg('eval')) {
 501                         my @list = split /\n/, $eval;
 502                         my $line;
 503                         for (@list) {
 504                                 dbg('eval', $_, "\n");
 505                         }
 506                 }
 507
 508                 {
 509                         #hide our variables within this block
 510                         my($filename,$mtime,$package,$sub);
 511                         eval $eval;
 512                 }
 513
 514                 if ($@) {
 515                         print "\$\@ = $@";
 516                         $errstr = $@;
 517                         delete_package($package);
 518                 } else {
 519                         #cache it unless we're cleaning out each time
 520                         $Cache{$package}{'mtime'} = $mtime;
 521                 }
 522         }
 523
 524         #print Devel::Symdump->rnew($package)->as_string, $/;
 525         $package = "DXCommandmode::$package" if $package;
 526         $package = undef if $errstr;
 527         return $package;
 528 }
 529
 530 1;
 531 __END__