perl/DXCommandmode.pm

   1 #!/usr/bin/perl
   2 #
   3 # This module impliments the user facing command mode for a dx cluster
   4 #
   5 # Copyright (c) 1998 Dirk Koopman G1TLH
   6 #
   7 #
   8 #
   9
  10 package DXCommandmode;
  11
  12 #use POSIX;
  13
  14 @ISA = qw(DXChannel);
  15
  16 use 5.10.1;
  17
  18 use POSIX qw(:math_h);
  19 use DXUtil;
  20 use DXChannel;
  21 use DXUser;
  22 use DXVars;
  23 use DXDebug;
  24 use DXM;
  25 use DXLog;
  26 use DXLogPrint;
  27 use DXBearing;
  28 use CmdAlias;
  29 use Filter;
  30 use Minimuf;
  31 use DXDb;
  32 use AnnTalk;
  33 use WCY;
  34 use Sun;
  35 use Internet;
  36 use Script;
  37 use QSL;
  38 use DB_File;
  39 use VE7CC;
  40 use DXXml;
  41 use AsyncMsg;
  42 use JSON;
  43 use Time::HiRes qw(gettimeofday tv_interval);
  44
  45 use Mojo::IOLoop;
  46 use DXSubprocess;
  47 use Mojo::UserAgent;
  48
  49 use strict;
  50 use vars qw(%Cache %cmd_cache $errstr %aliases $scriptbase %nothereslug
  51         $maxbadcount $msgpolltime $default_pagelth $cmdimportdir $users $maxusers);
  52
  53 %Cache = ();                                    # cache of dynamically loaded routine's mod times
  54 %cmd_cache = ();                                # cache of short names
  55 $errstr = ();                                   # error string from eval
  56 %aliases = ();                                  # aliases for (parts of) commands
  57 $scriptbase = "$main::root/scripts"; # the place where all users start scripts go
  58 $maxbadcount = 3;                               # no of bad words allowed before disconnection
  59 $msgpolltime = 3600;                    # the time between polls for new messages
  60 $cmdimportdir = "$main::root/cmd_import"; # the base directory for importing command scripts
  61                                           # this does not exist as default, you need to create it manually
  62 $users = 0;                                       # no of users on this node currently
  63 $maxusers = 0;                            # max no users on this node for this run
  64
  65 #
  66 # obtain a new connection this is derived from dxchannel
  67 #
  68
  69 sub new
  70 {
  71         my $self = DXChannel::alloc(@_);
  72
  73         # routing, this must go out here to prevent race condx
  74         my $pkg = shift;
  75         my $call = shift;
  76 #       my @rout = $main::routeroot->add_user($call, Route::here(1));
  77         DXProt::_add_thingy($main::routeroot, [$call, 0, 0, 1, undef, undef, $self->hostname], );
  78
  79         # ALWAYS output the user
  80         my $ref = Route::User::get($call);
  81         if ($ref) {
  82                 $main::me->route_pc16($main::mycall, undef, $main::routeroot, $ref);
  83                 $main::me->route_pc92a($main::mycall, undef, $main::routeroot, $ref) unless $DXProt::pc92_slug_changes;
  84         }
  85
  86         return $self;
  87 }
  88
  89 # this is how a a connection starts, you get a hello message and the motd with
  90 # possibly some other messages asking you to set various things up if you are
  91 # new (or nearly new and slacking) user.
  92
  93 sub start
  94 {
  95         my ($self, $line, $sort) = @_;
  96         my $user = $self->{user};
  97         my $call = $self->{call};
  98         my $name = $user->{name};
  99
 100         # log it
 101         my $host = $self->{conn}->peerhost;
 102         $host ||= "AGW Port #$self->{conn}->{agwport}" if exists $self->{conn}->{agwport};
 103         $host ||= "unknown";
 104         $self->{hostname} = $host;
 105
 106         $self->{name} = $name ? $name : $call;
 107         $self->send($self->msg('l2',$self->{name}));
 108         $self->state('prompt');         # a bit of room for further expansion, passwords etc
 109         $self->{priv} = $user->priv || 0;
 110         $self->{lang} = $user->lang || $main::lang || 'en';
 111         my $pagelth = $user->pagelth;
 112         $pagelth = $default_pagelth unless defined $pagelth;
 113         $self->{pagelth} = $pagelth;
 114         ($self->{width}) = $line =~ /\s*width=(\d+)/; $line =~ s/\s*width=\d+//;
 115         $self->{enhanced} = $line =~ /\s+enhanced/; $line =~ s/\s*enhanced//;
 116         if ($line =~ /host=/) {
 117                 my ($h) = $line =~ /host=(\d+\.\d+\.\d+\.\d+)/;
 118                 $line =~ s/\s*host=\d+\.\d+\.\d+\.\d+// if $h;
 119                 unless ($h) {
 120                         ($h) = $line =~ /host=([\da..fA..F:]+)/;
 121                         $line =~ s/\s*host=[\da..fA..F:]+// if $h;
 122                 }
 123                 $self->{hostname} = $h if $h;
 124         }
 125         $self->{width} = 80 unless $self->{width} && $self->{width} > 80;
 126         $self->{consort} = $line;       # save the connection type
 127
 128         LogDbg('DXCommand', "$call connected from $self->{hostname} cols $self->{width}" . ($self->{enhanced}?" enhanced":''));
 129
 130         # set some necessary flags on the user if they are connecting
 131         $self->{beep} = $user->wantbeep;
 132         $self->{ann} = $user->wantann;
 133         $self->{wwv} = $user->wantwwv;
 134         $self->{wcy} = $user->wantwcy;
 135         $self->{talk} = $user->wanttalk;
 136         $self->{wx} = $user->wantwx;
 137         $self->{dx} = $user->wantdx;
 138         $self->{logininfo} = $user->wantlogininfo;
 139         $self->{ann_talk} = $user->wantann_talk;
 140         $self->{wantrbn} = $user->wantrbn;
 141         $self->{here} = 1;
 142         $self->{prompt} = $user->prompt if $user->prompt;
 143         $self->{lastmsgpoll} = 0;
 144
 145         # sort out new dx spot stuff
 146         $user->wantdxcq(0) unless defined $user->{wantdxcq};
 147         $user->wantdxitu(0) unless defined $user->{wantdxitu};
 148         $user->wantusstate(0) unless defined $user->{wantusstate};
 149
 150         # sort out registration
 151         if ($main::reqreg == 2) {
 152                 $self->{registered} = !$user->registered;
 153         } else {
 154                 $self->{registered} = $user->registered;
 155         }
 156
 157         # establish slug queue, if required
 158         $self->{sluggedpcs} = [];
 159         $self->{isslugged} = $DXProt::pc92_slug_changes + $DXProt::last_pc92_slug + 5 if $DXProt::pc92_slug_changes;
 160         $self->{isslugged} = 0 if $self->{priv} > 0 || $user->registered || $user->homenode eq $main::mycall;
 161
 162         # send the relevant MOTD
 163         $self->send_motd;
 164
 165         # sort out privilege reduction
 166         $self->{priv} = 0 unless $self->{hostname} eq '127.0.0.1' || $self->{hostname} eq '::1' || $self->conn->{usedpasswd};
 167
 168         # get the filters
 169         my $nossid = $call;
 170         $nossid =~ s/-\d+$//;
 171
 172         $self->{spotsfilter} = Filter::read_in('spots', $call, 0)
 173                 || Filter::read_in('spots', $nossid, 0)
 174                         || Filter::read_in('spots', 'user_default', 0);
 175         $self->{wwvfilter} = Filter::read_in('wwv', $call, 0)
 176                 || Filter::read_in('wwv', $nossid, 0)
 177                         || Filter::read_in('wwv', 'user_default', 0);
 178         $self->{wcyfilter} = Filter::read_in('wcy', $call, 0)
 179                 || Filter::read_in('wcy', $nossid, 0)
 180                         || Filter::read_in('wcy', 'user_default', 0);
 181         $self->{annfilter} = Filter::read_in('ann', $call, 0)
 182                 || Filter::read_in('ann', $nossid, 0)
 183                         || Filter::read_in('ann', 'user_default', 0) ;
 184         $self->{rbnfilter} = Filter::read_in('rbn', $call, 0)
 185                 || Filter::read_in('rbn', $nossid, 0)
 186                 || Filter::read_in('rbn', 'user_default', 0);
 187
 188         # clean up qra locators
 189         my $qra = $user->qra;
 190         $qra = undef if ($qra && !DXBearing::is_qra($qra));
 191         unless ($qra) {
 192                 my $lat = $user->lat;
 193                 my $long = $user->long;
 194                 $user->qra(DXBearing::lltoqra($lat, $long)) if (defined $lat && defined $long);
 195         }
 196
 197         # decide on echo
 198         my $echo = $user->wantecho;
 199         unless ($echo) {
 200                 $self->send_now('E', "0");
 201                 $self->send($self->msg('echow'));
 202                 $self->conn->echo($echo) if $self->conn->can('echo');
 203         }
 204
 205         $self->tell_login('loginu');
 206         $self->tell_buddies('loginb');
 207
 208         # do we need to send a forward/opernam?
 209         my $lastoper = $user->lastoper || 0;
 210         my $homenode = $user->homenode || "";
 211         if ($homenode eq $main::mycall && $main::systime >= $lastoper + $DXUser::lastoperinterval) {
 212                 run_cmd($main::me, "forward/opernam $call");
 213                 $user->lastoper($main::systime + ((int rand(10)) * 86400));
 214         }
 215
 216         # run a script send the output to the punter
 217         my $script = new Script(lc $call) || new Script('user_default');
 218         $script->run($self) if $script;
 219
 220         # send cluster info
 221         $self->send($self->run_cmd("show/cluster"));
 222
 223         # send prompts for qth, name and things
 224         $self->send($self->msg('namee1')) if !$user->name;
 225         $self->send($self->msg('qthe1')) if !$user->qth;
 226         $self->send($self->msg('qll')) if !$user->qra || (!$user->lat && !$user->long);
 227         $self->send($self->msg('hnodee1')) if !$user->qth;
 228         $self->send($self->msg('m9')) if DXMsg::for_me($call);
 229
 230         # send out any buddy messages for other people that are online
 231         foreach my $call (@{$user->buddies}) {
 232                 my $ref = Route::User::get($call);
 233                 if ($ref) {
 234                         foreach my $node ($ref->parents) {
 235                                 $self->send($self->msg($node eq $main::mycall ? 'loginb' : 'loginbn', $call, $node));
 236                         }
 237                 }
 238         }
 239
 240         $self->lastmsgpoll($main::systime);
 241         $self->prompt;
 242 }
 243
 244 #
 245 # This is the normal command prompt driver
 246 #
 247
 248 sub normal
 249 {
 250         my $self = shift;
 251         my $cmdline = shift;
 252         my @ans;
 253
 254         # save this for them's that need it
 255         my $rawline = $cmdline;
 256
 257         # remove leading and trailing spaces
 258         $cmdline =~ s/^\s*(.*)\s*$/$1/;
 259
 260         if ($self->{state} eq 'page') {
 261                 my $i = $self->{pagelth};
 262                 my $ref = $self->{pagedata};
 263                 my $tot = @$ref;
 264
 265                 # abort if we get a line starting in with a
 266                 if ($cmdline =~ /^a/io) {
 267                         undef $ref;
 268                         $i = 0;
 269                 }
 270
 271                 # send a tranche of data
 272                 while ($i-- > 0 && @$ref) {
 273                         my $line = shift @$ref;
 274                         $line =~ s/\s+$//o;     # why am having to do this?
 275                         $self->send($line);
 276                 }
 277
 278                 # reset state if none or else chuck out an intermediate prompt
 279                 if ($ref && @$ref) {
 280                         $tot -= $self->{pagelth};
 281                         $self->send($self->msg('page', $tot));
 282                 } else {
 283                         $self->state('prompt');
 284                 }
 285         } elsif ($self->{state} eq 'sysop') {
 286                 my $passwd = $self->{user}->passwd;
 287                 if ($passwd) {
 288                         my @pw = grep {$_ !~ /\s/} split //, $passwd;
 289                         my @l = @{$self->{passwd}};
 290                         my $str = "$pw[$l[0]].*$pw[$l[1]].*$pw[$l[2]].*$pw[$l[3]].*$pw[$l[4]]";
 291                         if ($cmdline =~ /$str/) {
 292                                 $self->{priv} = $self->{user}->priv;
 293                         } else {
 294                                 $self->send($self->msg('sorry'));
 295                         }
 296                 } else {
 297                         $self->send($self->msg('sorry'));
 298                 }
 299                 $self->state('prompt');
 300         } elsif ($self->{state} eq 'passwd') {
 301                 my $passwd = $self->{user}->passwd;
 302                 if ($passwd && $cmdline eq $passwd) {
 303                         $self->send($self->msg('pw1'));
 304                         $self->state('passwd1');
 305                 } else {
 306                         $self->conn->{echo} = $self->conn->{decho};
 307                         delete $self->conn->{decho};
 308                         $self->send($self->msg('sorry'));
 309                         $self->state('prompt');
 310                 }
 311         } elsif ($self->{state} eq 'passwd1') {
 312                 $self->{passwd} = $cmdline;
 313                 $self->send($self->msg('pw2'));
 314                 $self->state('passwd2');
 315         } elsif ($self->{state} eq 'passwd2') {
 316                 if ($cmdline eq $self->{passwd}) {
 317                         $self->{user}->passwd($cmdline);
 318                         $self->send($self->msg('pw3'));
 319                 } else {
 320                         $self->send($self->msg('pw4'));
 321                 }
 322                 $self->conn->{echo} = $self->conn->{decho};
 323                 delete $self->conn->{decho};
 324                 $self->state('prompt');
 325         } elsif ($self->{state} eq 'talk' || $self->{state} eq 'chat') {
 326                 if ($cmdline =~ m{^(?:/EX|/ABORT)}i) {
 327                         for (@{$self->{talklist}}) {
 328                                 if ($self->{state} eq 'talk') {
 329                                         $self->send_talks($_,  $self->msg('talkend'));
 330                                 } else {
 331                                         $self->local_send('C', $self->msg('chatend', $_));
 332                                 }
 333                         }
 334                         $self->state('prompt');
 335                         delete $self->{talklist};
 336                 } elsif ($cmdline =~ m|^/+\w+|) {
 337                         $cmdline =~ s|^/||;
 338                         my $sendit = $cmdline =~ s|^/+||;
 339                         my @in = $self->run_cmd($cmdline);
 340                         $self->send_ans(@in);
 341                         if ($sendit && $self->{talklist} && @{$self->{talklist}}) {
 342                                 foreach my $l (@in) {
 343                                         my @bad;
 344                                         if (@bad = BadWords::check($l)) {
 345                                                 $self->badcount(($self->badcount||0) + @bad);
 346                                                 LogDbg('DXCommand', "$self->{call} swore: $l with words:" . join(',', @bad) . ")");
 347                                         } else {
 348                                                 for (@{$self->{talklist}}) {
 349                                                         if ($self->{state} eq 'talk') {
 350                                                                 $self->send_talks($_, $l);
 351                                                         } else {
 352                                                                 send_chats($self, $_, $l)
 353                                                         }
 354                                                 }
 355                                         }
 356                                 }
 357                         }
 358                         $self->send($self->{state} eq 'talk' ? $self->talk_prompt : $self->chat_prompt);
 359                 } elsif ($self->{talklist} && @{$self->{talklist}}) {
 360                         # send what has been said to whoever is in this person's talk list
 361                         my @bad;
 362                         if (@bad = BadWords::check($cmdline)) {
 363                                 $self->badcount(($self->badcount||0) + @bad);
 364                                 LogDbg('DXCommand', "$self->{call} swore: $cmdline with words:" . join(',', @bad) . ")");
 365                         } else {
 366                                 for (@{$self->{talklist}}) {
 367                                         if ($self->{state} eq 'talk') {
 368                                                 $self->send_talks($_, $rawline);
 369                                         } else {
 370                                                 send_chats($self, $_, $rawline);
 371                                         }
 372                                 }
 373                         }
 374                         $self->send($self->talk_prompt) if $self->{state} eq 'talk';
 375                         $self->send($self->chat_prompt) if $self->{state} eq 'chat';
 376                 } else {
 377                         # for safety
 378                         $self->state('prompt');
 379                 }
 380         } elsif (my $func = $self->{func}) {
 381                 no strict 'refs';
 382                 my @ans;
 383                 if (ref $self->{edit}) {
 384                         eval { @ans = $self->{edit}->$func($self, $rawline)};
 385                 } else {
 386                         eval {  @ans = &{$self->{func}}($self, $rawline) };
 387                 }
 388                 if ($@) {
 389                         $self->send_ans("Syserr: on stored func $self->{func}", $@);
 390                         delete $self->{func};
 391                         $self->state('prompt');
 392                         undef $@;
 393                 }
 394                 $self->send_ans(@ans);
 395         } else {
 396                 $self->send_ans(run_cmd($self, $cmdline));
 397         }
 398
 399         # check for excessive swearing
 400         if ($self->{badcount} && $self->{badcount} >= $maxbadcount) {
 401                 LogDbg('DXCommand', "$self->{call} logged out for excessive swearing");
 402                 $self->disconnect;
 403                 return;
 404         }
 405
 406         # send a prompt only if we are in a prompt state
 407         $self->prompt() if $self->{state} =~ /^prompt/o;
 408 }
 409
 410 # send out the talk messages taking into account vias and connectivity
 411 sub send_talks
 412 {
 413         my ($self, $ent, $line) = @_;
 414
 415         my ($to, $via) = $ent =~ /(\S+)>(\S+)/;
 416         $to = $ent unless $to;
 417         my $call = $via && $via ne '*' ? $via : $to;
 418         my $clref = Route::get($call);
 419         my $dxchan = $clref->dxchan if $clref;
 420         if ($dxchan) {
 421                 $dxchan->talk($self->{call}, $to, undef, $line);
 422         } else {
 423                 $self->send($self->msg('disc2', $via ? $via : $to));
 424                 my @l = grep { $_ ne $ent } @{$self->{talklist}};
 425                 if (@l) {
 426                         $self->{talklist} = \@l;
 427                 } else {
 428                         delete $self->{talklist};
 429                         $self->state('prompt');
 430                 }
 431         }
 432 }
 433
 434 sub send_chats
 435 {
 436         my $self = shift;
 437         my $target = shift;
 438         my $text = shift;
 439
 440         my $msgid = DXProt::nextchatmsgid();
 441         $text = "#$msgid $text";
 442         $main::me->normal(DXProt::pc93($target, $self->{call}, undef, $text));
 443 }
 444
 445 sub special_prompt
 446 {
 447         my $self = shift;
 448         my $prompt = shift;
 449         my @call;
 450         for (@{$self->{talklist}}) {
 451                 my ($to, $via) = /(\S+)>(\S+)/;
 452                 $to = $_ unless $to;
 453                 push @call, $to;
 454         }
 455         return $self->msg($prompt, join(',', @call));
 456 }
 457
 458 sub talk_prompt
 459 {
 460         my $self = shift;
 461         return $self->special_prompt('talkprompt');
 462 }
 463
 464 sub chat_prompt
 465 {
 466         my $self = shift;
 467         return $self->special_prompt('chatprompt');
 468 }
 469
 470 #
 471 # send a load of stuff to a command user with page prompting
 472 # and stuff
 473 #
 474
 475 sub send_ans
 476 {
 477         my $self = shift;
 478
 479         if ($self->{pagelth} && @_ > $self->{pagelth}) {
 480                 my $i;
 481                 for ($i = $self->{pagelth}; $i-- > 0; ) {
 482                         my $line = shift @_;
 483                         $line =~ s/\s+$//o;     # why am having to do this?
 484                         $self->send($line);
 485                 }
 486                 $self->{pagedata} =  [ @_ ];
 487                 $self->state('page');
 488                 $self->send($self->msg('page', scalar @_));
 489         } else {
 490                 for (@_) {
 491                         if (defined $_) {
 492                                 $self->send($_);
 493                         } else {
 494                                 $self->send('');
 495                         }
 496                 }
 497         }
 498 }
 499
 500 #
 501 # this is the thing that preps for running the command, it is done like this for the
 502 # benefit of remote command execution
 503 #
 504
 505 sub run_cmd
 506 {
 507         my $self = shift;
 508         my $user = $self->{user};
 509         my $call = $self->{call};
 510         my $cmdline = shift;
 511         my @ans;
 512
 513         return () if length $cmdline == 0;
 514
 515         # split the command line up into parts, the first part is the command
 516         my ($cmd, $args) = split /\s+/, $cmdline, 2;
 517         $args = "" unless defined $args;
 518
 519         if ($cmd) {
 520
 521                 # check cmd
 522                 if ($cmd =~ m|^/| || $cmd =~ m|[^-?\w/]|) {
 523                         LogDbg('DXCommand', "cmd: $self->{call} - invalid characters in '$cmd'");
 524                         return $self->_error_out('e1');
 525                 }
 526
 527                 # strip out // on command only
 528                 $cmd =~ s|//|/|g;
 529
 530                 my ($path, $fcmd);
 531
 532                 dbg("cmd: $cmd") if isdbg('command');
 533
 534                 # alias it if possible
 535                 my $acmd = CmdAlias::get_cmd($cmd);
 536                 if ($acmd) {
 537                         ($cmd, $args) = split /\s+/, "$acmd $args", 2;
 538                         $args = "" unless defined $args;
 539                         dbg("cmd: aliased $cmd $args") if isdbg('command');
 540                 }
 541
 542                 # first expand out the entry to a command
 543                 ($path, $fcmd) = search($main::localcmd, $cmd, "pl");
 544                 ($path, $fcmd) = search($main::cmd, $cmd, "pl") unless $path && $fcmd;
 545
 546                 if ($path && $cmd) {
 547                         dbg("cmd: path $cmd cmd: $fcmd") if isdbg('command');
 548
 549                         my $package = find_cmd_name($path, $fcmd);
 550                         return ($@) if $@;
 551
 552                         if ($package && $self->can("${package}::handle")) {
 553                                 no strict 'refs';
 554                                 dbg("cmd: package $package") if isdbg('command');
 555 #                               Log('cmd', "$self->{call} on $self->{hostname} : '$cmd $args'");
 556                                 my $t0 = [gettimeofday];
 557                                 eval { @ans = &{"${package}::handle"}($self, $args) };
 558                                 if ($@) {
 559                                         DXDebug::dbgprintring(25);
 560                                         return (DXDebug::shortmess($@));
 561                                 }
 562                                 if (isdbg('progress')) {
 563                                         my $msecs = _diffms($t0);
 564                                         my $s = "CMD: '$cmd $args' by $call ip: $self->{hostname} ${msecs}mS";
 565                                         dbg($s) if $cmd !~ /^(?:echo|blank)/ || isdbg('echo');     # cut down a bit on HRD and other clients' noise
 566                                 }
 567                         } else {
 568                                 dbg("cmd: $package not present") if isdbg('command');
 569                                 return $self->_error_out('e1');
 570                         }
 571                 } else {
 572                         dbg("cmd: $cmd not found") if isdbg('command');
 573                         return $self->_error_out('e1');
 574                 }
 575         }
 576
 577         my $ok = shift @ans;
 578         if ($ok) {
 579                 delete $self->{errors};
 580         } else {
 581                 if (++$self->{errors} > $DXChannel::maxerrors) {
 582                         $self->send($self->msg('e26'));
 583                         $self->disconnect;
 584                         return ();
 585                 }
 586         }
 587         return map {s/([^\s])\s+$/$1/; $_} @ans;
 588 }
 589
 590 #
 591 # This is called from inside the main cluster processing loop and is used
 592 # for despatching commands that are doing some long processing job
 593 #
 594 sub process
 595 {
 596         my $t = time;
 597         my @dxchan = DXChannel::get_all();
 598         my $dxchan;
 599
 600         $users = 0;
 601         foreach $dxchan (@dxchan) {
 602                 next unless $dxchan->is_user;
 603
 604                 # send a outstanding message prompt if required
 605                 if ($t >= $dxchan->lastmsgpoll + $msgpolltime) {
 606                         $dxchan->send($dxchan->msg('m9')) if DXMsg::for_me($dxchan->call);
 607                         $dxchan->lastmsgpoll($t);
 608                 }
 609
 610                 # send a prompt if no activity out on this channel
 611                 if ($t >= $dxchan->t + $main::user_interval) {
 612                         $dxchan->prompt() if $dxchan->{state} =~ /^prompt/o;
 613                         $dxchan->t($t);
 614                 }
 615                 ++$users;
 616                 $maxusers = $users if $users > $maxusers;
 617
 618                 if ($dxchan->{isslugged} && $main::systime > $dxchan->{isslugged}) {
 619                         foreach my $ref (@{$dxchan->{sluggedpcs}}) {
 620                                 if ($ref->[0] == 61) {
 621                                         Spot::add(@{$ref->[2]});
 622                                         DXProt::send_dx_spot($dxchan, $ref->[1], @{$ref->[2]});
 623                                 }
 624                         }
 625
 626                         $dxchan->{isslugged} = 0;
 627                         $dxchan->{sluggedpcs} = [];
 628                 }
 629         }
 630
 631         import_cmd();
 632 }
 633
 634 #
 635 # finish up a user context
 636 #
 637 sub disconnect
 638 {
 639         my $self = shift;
 640         my $call = $self->call;
 641
 642         return if $self->{disconnecting}++;
 643
 644         delete $self->{senddbg};
 645
 646         my $uref = Route::User::get($call);
 647         my @rout;
 648         if ($uref) {
 649 #               @rout = $main::routeroot->del_user($uref);
 650                 @rout = DXProt::_del_thingy($main::routeroot, [$call, 0]);
 651
 652                 dbg("B/C PC17 on $main::mycall for: $call") if isdbg('route');
 653
 654                 # issue a pc17 to everybody interested
 655                 $main::me->route_pc17($main::mycall, undef, $main::routeroot, $uref);
 656                 $main::me->route_pc92d($main::mycall, undef, $main::routeroot, $uref) unless $DXProt::pc92_slug_changes;
 657         } else {
 658                 confess "trying to disconnect a non existant user $call";
 659         }
 660
 661         # I was the last node visited
 662     $self->user->node($main::mycall);
 663
 664         # send info to all logged in thingies
 665         $self->tell_login('logoutu');
 666         $self->tell_buddies('logoutb');
 667
 668         LogDbg('DXCommand', "$call disconnected");
 669
 670         $self->SUPER::disconnect;
 671 }
 672
 673 #
 674 # short cut to output a prompt
 675 #
 676
 677 sub prompt
 678 {
 679         my $self = shift;
 680
 681         return if $self->{gtk};         # 'cos prompts are not a concept that applies here
 682
 683         my $call = $self->call;
 684         my $date = cldate($main::systime);
 685         my $time = ztime($main::systime);
 686         my $prompt = $self->{prompt} || $self->msg('pr');
 687
 688         $call = "($call)" unless $self->here;
 689         $prompt =~ s/\%C/$call/g;
 690         $prompt =~ s/\%D/$date/g;
 691         $prompt =~ s/\%T/$time/g;
 692         $prompt =~ s/\%M/$main::mycall/g;
 693
 694         $self->send($prompt);
 695 }
 696
 697 # broadcast a message to all users [except those mentioned after buffer]
 698 sub broadcast
 699 {
 700         my $pkg = shift;                        # ignored
 701         my $s = shift;                          # the line to be rebroadcast
 702
 703     foreach my $dxchan (DXChannel::get_all()) {
 704                 next unless $dxchan->is_user; # only interested in user channels
 705                 next if grep $dxchan == $_, @_;
 706                 $dxchan->send($s);                      # send it
 707         }
 708 }
 709
 710 # gimme all the users
 711 sub get_all
 712 {
 713         goto &DXChannel::get_all_users;
 714 }
 715
 716 # run a script for this user
 717 sub run_script
 718 {
 719         my $self = shift;
 720         my $silent = shift || 0;
 721
 722 }
 723
 724 #
 725 # search for the command in the cache of short->long form commands
 726 #
 727
 728 sub search
 729 {
 730         my ($path, $short_cmd, $suffix) = @_;
 731         my ($apath, $acmd);
 732
 733         # commands are lower case
 734         $short_cmd = lc $short_cmd;
 735         dbg("command: $path $short_cmd\n") if isdbg('command');
 736
 737         # do some checking for funny characters
 738         return () if $short_cmd =~ /\/$/;
 739
 740         # return immediately if we have it
 741         ($apath, $acmd) = split ',', $cmd_cache{$short_cmd} if $cmd_cache{$short_cmd};
 742         if ($apath && $acmd) {
 743                 dbg("cached $short_cmd = ($apath, $acmd)\n") if isdbg('command');
 744                 return ($apath, $acmd);
 745         }
 746
 747         # if not guess
 748         my @parts = split '/', $short_cmd;
 749         my $dirfn;
 750         my $curdir = $path;
 751
 752         while (my $p = shift @parts) {
 753                 opendir(D, $curdir) or confess "can't open $curdir $!";
 754                 my @ls = readdir D;
 755                 closedir D;
 756
 757                 # if this isn't the last part
 758                 if (@parts) {
 759                         my $found;
 760                         foreach my $l (sort @ls) {
 761                                 next if $l =~ /^\./;
 762                                 if ((-d "$curdir/$l") && $p eq substr($l, 0, length $p)) {
 763                                         dbg("got dir: $curdir/$l\n") if isdbg('command');
 764                                         $dirfn .= "$l/";
 765                                         $curdir .= "/$l";
 766                                         $found++;
 767                                         last;
 768                                 }
 769                         }
 770                         # only proceed if we find the directory asked for
 771                         return () unless $found;
 772                 } else {
 773                         foreach my $l (sort @ls) {
 774                                 next if $l =~ /^\./;
 775                                 next unless $l =~ /\.$suffix$/;
 776                                 if ($p eq substr($l, 0, length $p)) {
 777                                         $l =~ s/\.$suffix$//;
 778                                         $dirfn = "" unless $dirfn;
 779                                         $cmd_cache{$short_cmd} = join(',', ($path, "$dirfn$l")); # cache it
 780                                         dbg("got path: $path cmd: $dirfn$l\n") if isdbg('command');
 781                                         return ($path, "$dirfn$l");
 782                                 }
 783                         }
 784                 }
 785         }
 786
 787         return ();
 788 }
 789
 790 # clear the command name cache
 791 sub clear_cmd_cache
 792 {
 793         no strict 'refs';
 794
 795         for my $k (keys %Cache) {
 796                 unless ($k =~ /cmd_cache/) {
 797                         dbg("Undefining cmd $k") if isdbg('command');
 798                         undef $DXCommandmode::{"${k}::"};
 799                 }
 800         }
 801         %cmd_cache = ();
 802         %Cache = ( cmd_clear_cmd_cache  => $Cache{cmd_clear_cmd_cache} );
 803 }
 804
 805 #
 806 # the persistant execution of things from the command directories
 807 #
 808 #
 809 # This allows perl programs to call functions dynamically
 810 #
 811 # This has been nicked directly from the perlembed pages
 812 #
 813 #require Devel::Symdump;
 814
 815 sub valid_package_name {
 816         my $string = shift;
 817         $string =~ s|([^A-Za-z0-9_/])|sprintf("_%2x",unpack("C",$1))|eg;
 818
 819         $string =~ s|/|_|g;
 820         return "cmd_$string";
 821 }
 822
 823 #
 824 # this bit of magic finds a command in the offered directory
 825 sub find_cmd_name {
 826         my $path = shift;
 827         my $cmdname = shift;
 828         my $package = valid_package_name($cmdname);
 829         my $filename = "$path/$cmdname.pl";
 830         my $mtime = -M $filename;
 831
 832         # return if we can't find it
 833         $errstr = undef;
 834         unless (defined $mtime) {
 835                 $errstr = DXM::msg('e1');
 836                 return undef;
 837         }
 838
 839         if(exists $Cache{$package} && exists $Cache{$package}->{mtime} && $Cache{$package}->{mtime} <= $mtime) {
 840                 #we have compiled this subroutine already,
 841                 #it has not been updated on disk, nothing left to do
 842                 #print STDERR "already compiled $package->handler\n";
 843                 dbg("find_cmd_name: $package cached") if isdbg('command');
 844         } else {
 845
 846                 my $sub = readfilestr($filename);
 847                 unless ($sub) {
 848                         $errstr = "Syserr: can't open '$filename' $!";
 849                         return undef;
 850                 };
 851
 852                 #wrap the code into a subroutine inside our unique package
 853                 my $eval = qq(package DXCommandmode::$package; use 5.10.1; use POSIX qw{:math_h}; use DXLog; use DXDebug; use DXUser; use DXUtil; our \@ISA = qw{DXCommandmode}; );
 854
 855
 856                 if ($sub =~ m|\s*sub\s+handle\n|) {
 857                         $eval .= $sub;
 858                 } else {
 859                         $eval .= qq(sub handle { $sub });
 860                 }
 861
 862                 if (isdbg('eval')) {
 863                         my @list = split /\n/, $eval;
 864                         my $line;
 865                         for (@list) {
 866                                 dbg($_ . "\n") if isdbg('eval');
 867                         }
 868                 }
 869
 870                 # get rid of any existing sub and try to compile the new one
 871                 no strict 'refs';
 872
 873                 if (exists $Cache{$package}) {
 874                         dbg("find_cmd_name: Redefining $package") if isdbg('command');
 875                         undef $DXCommandmode::{"${package}::"};
 876                         delete $Cache{$package};
 877                 } else {
 878                         dbg("find_cmd_name: Defining $package") if isdbg('command');
 879                 }
 880
 881                 eval $eval;
 882
 883                 $Cache{$package} = {mtime => $mtime } unless $@;
 884         }
 885
 886         return "DXCommandmode::$package";
 887 }
 888
 889 sub send
 890 {
 891         my $self = shift;
 892         if ($self->{gtk}) {
 893                 for (@_) {
 894                         $self->SUPER::send(dd(['cmd',$_]));
 895                 }
 896         } else {
 897                 $self->SUPER::send(@_);
 898         }
 899 }
 900
 901 sub local_send
 902 {
 903         my ($self, $let, $buf) = @_;
 904         if ($self->{state} eq 'prompt' || $self->{state} eq 'talk' || $self->{state} eq 'chat') {
 905                 if ($self->{enhanced}) {
 906                         $self->send_later($let, $buf);
 907                 } else {
 908                         $self->send($buf);
 909                 }
 910         } else {
 911                 $self->delay($buf);
 912         }
 913 }
 914
 915 # send a talk message here
 916 sub talk
 917 {
 918         my ($self, $from, $to, $via, $line, $onode) = @_;
 919         $line =~ s/\\5E/\^/g;
 920         if ($self->{talk}) {
 921                 if ($self->{gtk}) {
 922                         $self->local_send('T', dd(['talk',$to,$from,$via,$line]));
 923                 } else {
 924                         $self->local_send('T', "$to de $from: $line");
 925                 }
 926         }
 927         Log('talk', $to, $from, '<' . ($onode || '*'), $line);
 928         # send a 'not here' message if required
 929         unless ($self->{here} && $from ne $to) {
 930                 my $key = "$to$from";
 931                 unless (exists $nothereslug{$key}) {
 932                         my ($ref, $dxchan);
 933                         if (($ref = Route::get($from)) && ($dxchan = $ref->dxchan)) {
 934                                 my $name = $self->user->name || $to;
 935                                 my $s = $self->user->nothere || $dxchan->msg('nothere', $name);
 936                                 $nothereslug{$key} = $main::systime;
 937                                 $dxchan->talk($to, $from, undef, $s);
 938                         }
 939                 }
 940         }
 941 }
 942
 943 # send an announce
 944 sub announce
 945 {
 946         my $self = shift;
 947         my $line = shift;
 948         my $isolate = shift;
 949         my $to = shift;
 950         my $target = shift;
 951         my $text = shift;
 952         my ($filter, $hops);
 953
 954         if (!$self->{ann_talk} && $to ne $self->{call}) {
 955                 my $call = AnnTalk::is_talk_candidate($_[0], $text);
 956                 return if $call;
 957         }
 958
 959         if ($self->{annfilter}) {
 960                 ($filter, $hops) = $self->{annfilter}->it(@_ );
 961                 return unless $filter;
 962         }
 963
 964         unless ($self->{ann}) {
 965                 return if $_[0] ne $main::myalias && $_[0] ne $main::mycall;
 966         }
 967         return if $target eq 'SYSOP' && $self->{priv} < 5;
 968         my $buf;
 969         if ($self->{gtk}) {
 970                 $buf = dd(['ann', $to, $target, $text, @_])
 971         } else {
 972                 $buf = "$to$target de $_[0]: $text";
 973                 #$buf =~ s/\%5E/^/g;
 974                 $buf .= "\a\a" if $self->{beep};
 975         }
 976         $self->local_send($target eq 'WX' ? 'W' : 'N', $buf);
 977 }
 978
 979 # send a chat
 980 sub chat
 981 {
 982         my $self = shift;
 983         my $line = shift;
 984         my $isolate = shift;
 985         my $target = shift;
 986         my $to = shift;
 987         my $text = shift;
 988         my ($filter, $hops);
 989
 990         return unless grep uc $_ eq $target, @{$self->{user}->{group}};
 991
 992         $text =~ s/^\#\d+ //;
 993         my $buf;
 994         if ($self->{gtk}) {
 995                 $buf = dd(['chat', $to, $target, $text, @_])
 996         } else {
 997                 $buf = "$target de $_[0]: $text";
 998                 #$buf =~ s/\%5E/^/g;
 999                 $buf .= "\a\a" if $self->{beep};
1000         }
1001         $self->local_send('C', $buf);
1002 }
1003
1004 sub format_dx_spot
1005 {
1006         my $self = shift;
1007
1008         my $t = ztime($_[2]);
1009         my ($slot1, $slot2) = ('', '');
1010
1011         my $clth = 30 + $self->{width} - 80;    # allow comment to grow according the screen width
1012         my $comment = substr (($_[3] || ''), 0, $clth);
1013         $comment =~ s/\t/ /g;
1014         $comment .= ' ' x ($clth - (length($comment)));
1015
1016     if (!$slot1 && $self->{user}->wantgrid) {
1017                 my $ref = DXUser::get_current($_[1]);
1018                 if ($ref && $ref->qra) {
1019                         $slot1 = ' ' . substr($ref->qra, 0, 4);
1020                 }
1021         }
1022         if (!$slot1 && $self->{user}->wantusstate) {
1023                 $slot1 = " $_[12]" if $_[12];
1024         }
1025         unless ($slot1) {
1026                 if ($self->{user}->wantdxitu) {
1027                         $slot1 = sprintf(" %2d", $_[8]) if defined $_[8];
1028                 } elsif ($self->{user}->wantdxcq) {
1029                         $slot1 = sprintf(" %2d", $_[9]) if defined $_[9];
1030                 }
1031         }
1032         $comment = substr($comment, 0,  $clth-length($slot1)) . $slot1 if $slot1;
1033
1034     if (!$slot2 && $self->{user}->wantgrid) {
1035                 my $origin = $_[4];
1036                 $origin =~ s/-#$//;                     # sigh......
1037                 my $ref = DXUser::get_current($origin);
1038                 if ($ref && $ref->qra) {
1039                         $slot2 = ' ' . substr($ref->qra, 0, 4);
1040                 }
1041         }
1042         if (!$slot2 && $self->{user}->wantusstate) {
1043                 $slot2 = " $_[13]" if $_[13];
1044         }
1045         unless ($slot2) {
1046                 if ($self->{user}->wantdxitu) {
1047                         $slot2 = sprintf(" %2d", $_[10]) if defined $_[10];
1048                 } elsif ($self->{user}->wantdxcq) {
1049                         $slot2 = sprintf(" %2d", $_[11]) if defined $_[11];
1050                 }
1051         }
1052
1053         return sprintf "DX de %-8.8s%10.1f  %-12.12s %-s $t$slot2", "$_[4]:", $_[0], $_[1], $comment;
1054 }
1055
1056
1057 # send a dx spot
1058 sub dx_spot
1059 {
1060         my $self = shift;
1061         my $line = shift;
1062         my $isolate = shift;
1063         return unless $self->{dx};
1064
1065         my ($filter, $hops);
1066
1067         if ($self->{spotsfilter}) {
1068                 ($filter, $hops) = $self->{spotsfilter}->it(@_ );
1069                 return unless $filter;
1070         }
1071
1072         dbg('spot: "' . join('","', @_) . '"') if isdbg('dxspot');
1073
1074         my $buf;
1075         if ($self->{ve7cc}) {
1076                 $buf = VE7CC::dx_spot($self, @_);
1077         } elsif ($self->{gtk}) {
1078                 my ($dxloc, $byloc);
1079
1080                 my $ref = DXUser::get_current($_[4]);
1081                 if ($ref) {
1082                         $byloc = $ref->qra;
1083                         $byloc = substr($byloc, 0, 4) if $byloc;
1084                 }
1085
1086                 my $spot = $_[1];
1087                 $spot =~ s|/\w{1,4}$||;
1088                 $ref = DXUser::get_current($spot);
1089                 if ($ref) {
1090                         $dxloc = $ref->qra;
1091                         $dxloc = substr($dxloc, 0, 4) if $dxloc;
1092                 }
1093                 $buf = dd(['dx', @_, ($dxloc||''), ($byloc||'')]);
1094
1095         } else {
1096                 $buf = $self->format_dx_spot(@_);
1097                 $buf .= "\a\a" if $self->{beep};
1098                 #$buf =~ s/\%5E/^/g;
1099         }
1100
1101         $self->local_send('X', $buf);
1102 }
1103
1104 sub wwv
1105 {
1106         my $self = shift;
1107         my $line = shift;
1108         my $isolate = shift;
1109         my ($filter, $hops);
1110
1111         return unless $self->{wwv};
1112
1113         if ($self->{wwvfilter}) {
1114                 ($filter, $hops) = $self->{wwvfilter}->it(@_[7..$#_] );
1115                 return unless $filter;
1116         }
1117
1118         my $buf;
1119         if ($self->{gtk}) {
1120                 $buf = dd(['wwv', @_])
1121         } else {
1122                 $buf = "WWV de $_[6] <$_[1]>:   SFI=$_[2], A=$_[3], K=$_[4], $_[5]";
1123                 $buf .= "\a\a" if $self->{beep};
1124         }
1125
1126         $self->local_send('V', $buf);
1127 }
1128
1129 sub wcy
1130 {
1131         my $self = shift;
1132         my $line = shift;
1133         my $isolate = shift;
1134         my ($filter, $hops);
1135
1136         return unless $self->{wcy};
1137
1138         if ($self->{wcyfilter}) {
1139                 ($filter, $hops) = $self->{wcyfilter}->it(@_ );
1140                 return unless $filter;
1141         }
1142
1143         my $buf;
1144         if ($self->{gtk}) {
1145                 $buf = dd(['wcy', @_])
1146         } else {
1147                 $buf = "WCY de $_[10] <$_[1]> : K=$_[4] expK=$_[5] A=$_[3] R=$_[6] SFI=$_[2] SA=$_[7] GMF=$_[8] Au=$_[9]";
1148                 $buf .= "\a\a" if $self->{beep};
1149         }
1150         $self->local_send('Y', $buf);
1151 }
1152
1153 # broadcast debug stuff to all interested parties
1154 sub broadcast_debug
1155 {
1156         my $s = shift;                          # the line to be rebroadcast
1157
1158         foreach my $dxchan (DXChannel::get_all_users) {
1159                 next unless $dxchan->{enhanced} && $dxchan->{senddbg};
1160                 if ($dxchan->{gtk}) {
1161                         $dxchan->send_later('L', dd(['db', $s]));
1162                 } else {
1163                         $dxchan->send_later('L', $s);
1164                 }
1165         }
1166 }
1167
1168 sub do_entry_stuff
1169 {
1170         my $self = shift;
1171         my $line = shift;
1172         my @out;
1173
1174         if ($self->state eq 'enterbody') {
1175                 my $loc = $self->{loc} || confess "local var gone missing" ;
1176                 if ($line eq "\032" || $line eq '%1A' || uc $line eq "/EX") {
1177                         no strict 'refs';
1178                         push @out, &{$loc->{endaction}}($self);          # like this for < 5.8.0
1179                         $self->func(undef);
1180                         $self->state('prompt');
1181                 } elsif ($line eq "\031" || uc $line eq "/ABORT" || uc $line eq "/QUIT") {
1182                         push @out, $self->msg('m10');
1183                         delete $loc->{lines};
1184                         delete $self->{loc};
1185                         $self->func(undef);
1186                         $self->state('prompt');
1187                 } else {
1188                         push @{$loc->{lines}}, length($line) > 0 ? $line : " ";
1189                         # i.e. it ain't and end or abort, therefore store the line
1190                 }
1191         } else {
1192                 confess "Invalid state $self->{state}";
1193         }
1194         return @out;
1195 }
1196
1197 sub store_startup_script
1198 {
1199         my $self = shift;
1200         my $loc = $self->{loc} || confess "local var gone missing" ;
1201         my @out;
1202         my $call = $loc->{call} || confess "callsign gone missing";
1203         confess "lines array gone missing" unless ref $loc->{lines};
1204         my $r = Script::store($call, $loc->{lines});
1205         if (defined $r) {
1206                 if ($r) {
1207                         push @out, $self->msg('m19', $call, $r);
1208                 } else {
1209                         push @out, $self->msg('m20', $call);
1210                 }
1211         } else {
1212                 push @out, "error opening startup script $call $!";
1213         }
1214         return @out;
1215 }
1216
1217 # Import any commands contained in any files in import_cmd directory
1218 #
1219 # If the filename has a recogisable callsign as some delimited part
1220 # of it, then this is the user the command will be run as.
1221 #
1222 sub import_cmd
1223 {
1224         # are there any to do in this directory?
1225         return unless -d $cmdimportdir;
1226         unless (opendir(DIR, $cmdimportdir)) {
1227                 LogDbg('err', "can\'t open $cmdimportdir $!");
1228                 return;
1229         }
1230
1231         my @names = readdir(DIR);
1232         closedir(DIR);
1233         my $name;
1234
1235         return unless @names;
1236
1237         foreach $name (@names) {
1238                 next if $name =~ /^\./;
1239
1240                 my $s = Script->new($name, $cmdimportdir);
1241                 if ($s) {
1242                         LogDbg('DXCommand', "Run import cmd file $name");
1243                         my @cat = split /[^A-Za-z0-9]+/, $name;
1244                         my ($call) = grep {is_callsign(uc $_)} @cat;
1245                         $call ||= $main::mycall;
1246                         $call = uc $call;
1247                         my @out;
1248
1249
1250                         $s->inscript(0);        # switch off script checks
1251
1252                         if ($call eq $main::mycall) {
1253                                 @out = $s->run($main::me, 1);
1254                         } else {
1255                                 my $dxchan = DXChannel::get($call);
1256                             if ($dxchan) {
1257                                         @out = $s->run($dxchan, 1);
1258                                 } else {
1259                                         my $u = DXUser::get($call);
1260                                         if ($u) {
1261                                                 $dxchan = $main::me;
1262                                                 my $old = $dxchan->{call};
1263                                                 my $priv = $dxchan->{priv};
1264                                                 my $user = $dxchan->{user};
1265                                                 $dxchan->{call} = $call;
1266                                                 $dxchan->{priv} = $u->priv;
1267                                                 $dxchan->{user} = $u;
1268                                                 @out = $s->run($dxchan, 1);
1269                                                 $dxchan->{call} = $old;
1270                                                 $dxchan->{priv} = $priv;
1271                                                 $dxchan->{user} = $user;
1272                                         } else {
1273                                                 LogDbg('err', "Trying to run import cmd for non-existant user $call");
1274                                         }
1275                                 }
1276                         }
1277                         $s->erase;
1278                         for (@out) {
1279                                 LogDbg('DXCommand', "Import cmd $name/$call: $_");
1280                         }
1281                 } else {
1282                         LogDbg('err', "Failed to open $cmdimportdir/$name $!");
1283                         unlink "$cmdimportdir/$name";
1284                 }
1285         }
1286 }
1287
1288 sub print_find_reply
1289 {
1290         my ($self, $node, $target, $flag, $ms) = @_;
1291         my $sort = $flag == 2 ? "External" : "Local";
1292         $self->send("$sort $target found at $node in $ms ms" );
1293 }
1294
1295 # send the most relevant motd
1296 sub send_motd
1297 {
1298         my $self = shift;
1299         my $motd;
1300
1301         unless ($self->isregistered) {
1302                 $motd = "${main::motd}_nor_$self->{lang}";
1303                 $motd = "${main::motd}_nor" unless -e $motd;
1304         }
1305         $motd = "${main::motd}_$self->{lang}" unless $motd && -e $motd;
1306         $motd = $main::motd unless $motd && -e $motd;
1307         if ($self->conn->ax25) {
1308                 if ($motd) {
1309                         $motd = "${motd}_ax25" if -e "${motd}_ax25";
1310                 } else {
1311                         $motd = "${main::motd}_ax25" if -e "${main::motd}_ax25";
1312                 }
1313         }
1314         $self->send_file($motd) if -e $motd;
1315 }
1316
1317
1318 # Punt off a long running command into a separate process
1319 #
1320 # This is called from commands to run some potentially long running
1321 # function. The process forks and then runs the function and returns
1322 # the result back to the cmd.
1323 #
1324 # NOTE: this merely forks the current process and then runs the cmd in that (current) context.
1325 #       IT DOES NOT START UP SOME NEW PROGRAM AND RELIES ON THE FACT THAT IT IS RUNNING DXSPIDER
1326 #       THE CURRENT CONTEXT!!
1327 #
1328 # call: $self->spawn_cmd($original_cmd_line, \<function>, [cb => sub{...}], [prefix => "cmd> "], [progress => 0|1], [args => [...]]);
1329 sub spawn_cmd
1330 {
1331         my $self = shift;
1332         my $line = shift;
1333         my $cmdref = shift;
1334         my $call = $self->{call};
1335         my %args = @_;
1336         my @out;
1337
1338         my $cb = delete $args{cb};
1339         my $prefix = delete $args{prefix};
1340         my $progress = delete $args{progress};
1341         my $args = delete $args{args} || [];
1342         my $t0 = [gettimeofday];
1343
1344         no strict 'refs';
1345
1346         # just behave normally if something has set the "one-shot" _nospawn in the channel
1347         if ($self->{_nospawn}) {
1348                 eval { @out = $cmdref->(@$args); };
1349                 if ($@) {
1350                         DXDebug::dbgprintring(25);
1351                         push @out, DXDebug::shortmess($@);
1352                 }
1353                 return @out;
1354         }
1355
1356         my $fc = DXSubprocess->new;
1357 #       $fc->serializer(\&encode_json);
1358 #       $fc->deserializer(\&decode_json);
1359         $fc->run(
1360                          sub {
1361                                  my $subpro = shift;
1362                                  if (isdbg('progress')) {
1363                                          my $s = qq{$call line: "$line"};
1364                                          $s .= ", args: " . join(', ', map { defined $_ ? qq{'$_'} : q{'undef'} } @$args) if $args && @$args;
1365                                          dbg($s);
1366                                  }
1367                                  eval {
1368                                          ++$self->{_in_sub_process};
1369                                          dbg "\$self->{_in_sub_process} = $self->{_in_sub_process}";
1370                                          @out = $cmdref->(@$args);
1371                                          --$self->{_in_sub_process} if $self->{_in_sub_process} > 0;
1372                                  };
1373                                  if ($@) {
1374                                          DXDebug::dbgprintring(25);
1375                                          push @out, DXDebug::shortmess($@);
1376                                  }
1377                                  return @out;
1378                          },
1379 #                        $args,
1380                          sub {
1381                                  my ($fc, $err, @res) = @_;
1382                                  my $dxchan = DXChannel::get($call);
1383                                  return unless $dxchan;
1384
1385                                  if ($err) {
1386                                          my $s = "DXProt::spawn_cmd: call $call error $err";
1387                                          dbg($s) if isdbg('chan');
1388                                          $dxchan->send($s);
1389                                          return;
1390                                  }
1391                                  if ($cb) {
1392                                          # transform output if required
1393                                          @res = $cb->($dxchan, @res);
1394                                  }
1395                                  if (@res) {
1396                                          if (defined $prefix) {
1397                                                  $dxchan->send(map {"$prefix$_"} @res);
1398                                          } else {
1399                                                  $dxchan->send(@res);
1400                                          }
1401                                  }
1402                                  diffms("by $call", $line, $t0, scalar @res) if isdbg('progress');
1403                          });
1404
1405         return @out;
1406 }
1407
1408 sub user_count
1409 {
1410         return ($users, $maxusers);
1411 }
1412
1413 1;
1414 __END__