+# is called route(to, pcline);
+#
+
+sub route
+{
+ my ($self, $call, $line) = @_;
+
+ if (ref $self && $call eq $self->{call}) {
+ dbg("PCPROT: Trying to route back to source, dropped") if isdbg('chanerr');
+ return;
+ }
+
+ # always send it down the local interface if available
+ my $dxchan = DXChannel::get($call);
+ if ($dxchan) {
+ dbg("route: $call -> $dxchan->{call} direct" ) if isdbg('route');
+ } else {
+ my $cl = Route::get($call);
+ $dxchan = $cl->dxchan if $cl;
+ if (ref $dxchan) {
+ if (ref $self && $dxchan eq $self) {
+ dbg("PCPROT: Trying to route back to source, dropped") if isdbg('chanerr');
+ return;
+ }
+ dbg("route: $call -> $dxchan->{call} using normal route" ) if isdbg('route');
+ }
+ }
+
+ if ($dxchan) {
+ my $routeit = adjust_hops($dxchan, $line); # adjust its hop count by node name
+ if ($routeit) {
+ $dxchan->send($routeit) unless $dxchan == $main::me;
+ }
+ } else {
+ dbg("PCPROT: No route available, dropped") if isdbg('chanerr');
+ }
+}
+
+#
+# obtain the hops from the list for this callsign and pc no
+#
+
+sub get_hops
+{
+ my $pcno = shift;
+ my $hops = $DXProt::hopcount{$pcno};
+ $hops = $DXProt::def_hopcount if !$hops;
+ return "H$hops";
+}
+
+#
+# adjust the hop count on a per node basis using the user loadable
+# hop table if available or else decrement an existing one
+#
+
+sub adjust_hops
+{
+ my $self = shift;
+ my $s = shift;
+ my $call = $self->{call};
+ my $hops;
+
+ if (($hops) = $s =~ /\^H([-\d]+)\^?~?$/o) {
+ my ($pcno) = $s =~ /^PC(\d\d)/o;
+ confess "$call called adjust_hops with '$s'" unless $pcno;
+ my $ref = $nodehops{$call} if %nodehops;
+ if ($ref) {
+ my $newhops = $ref->{$pcno};
+ return "" if defined $newhops && $newhops == 0;
+ $newhops = $ref->{default} unless $newhops;
+ return "" if defined $newhops && $newhops == 0;
+ $newhops = $hops unless $newhops;
+ return "" unless $newhops > 0;
+ $s =~ s/\^H(\d+)(\^~?)$/\^H$newhops$2/ if $newhops != $hops;
+ } else {
+ return "" unless $hops > 0;
+ }
+ }
+ return $s;
+}
+
+#
+# load hop tables
+#
+sub load_hops
+{
+ my $self = shift;
+ return $self->msg('lh1') unless -e "$main::data/hop_table.pl";
+ do "$main::data/hop_table.pl";
+ return $@ if $@;
+ return ();
+}
+
+sub process_rcmd
+{
+ my ($self, $tonode, $fromnode, $user, $cmd) = @_;
+
+ if ($tonode eq $main::mycall) {
+ my $ref = DXUser::get_current($fromnode);
+ unless ($ref && UNIVERSAL::isa($ref, 'DXUser')) {
+ dbg("DXProt process_rcmd: user $fromnode isn't a reference (check user_asc and tell G1TLH)");
+ $self->send_rcmd_reply($main::mycall, $fromnode, $user, "sorry...!");
+ return;
+ }
+ Log('rcmd', 'in', ($ref->{priv}||0), $fromnode, $cmd, $user);
+ my $cref = Route::Node::get($fromnode);
+ unless ($cref && UNIVERSAL::isa($cref, 'Route')) {
+ dbg("DXProt process_rcmd: Route $fromnode isn't a reference (tell G1TLH)");
+ $self->send_rcmd_reply($main::mycall, $fromnode, $user, "sorry...!");
+ return;
+ }
+ if ($cmd !~ /^\s*rcmd/i && $ref->homenode && $cref->call eq $ref->homenode) { # not allowed to relay RCMDS!
+ if ($ref->{priv}) { # you have to have SOME privilege, the commands have further filtering
+ $self->{remotecmd} = 1; # for the benefit of any command that needs to know
+ my $oldpriv = $self->{priv};
+ $self->{priv} = 1; # set a maximum privilege
+
+ # park homenode and user for any spawned command that run_cmd may do.
+ $self->{_rcmd_user} = $user;
+ $self->{_rcmd_fromnode} = $fromnode;
+ my @in = (DXCommandmode::run_cmd($self, $cmd));
+ delete $self->{_rcmd_fromnode};
+ delete $self->{_rcmd_user};
+ $self->{priv} = $oldpriv;
+ $self->send_rcmd_reply($main::mycall, $fromnode, $user, @in);
+ delete $self->{remotecmd};
+ } else {
+ $self->send_rcmd_reply($main::mycall, $fromnode, $user, "sorry...!");
+ }
+ } else {
+ $self->send_rcmd_reply($main::mycall, $fromnode, $user, "your attempt is logged, Tut tut tut...!");
+ }
+ } else {
+ my $ref = DXUser::get_current($tonode);
+ if ($ref && $ref->is_clx) {
+ $self->route($tonode, pc84($fromnode, $tonode, $user, $cmd));
+ } else {
+ $self->route($tonode, pc34($fromnode, $tonode, $cmd));
+ }
+ }
+}
+
+
+sub send_rcmd_reply
+{
+ my $self = shift;
+ my $tonode = shift;
+ my $fromnode = shift;
+ my $user = shift;
+ while (@_) {
+ my $line = shift;
+ $line =~ s/\s*$//;
+ Log('rcmd', 'out', $fromnode, $line, $user);
+ if ($self->is_clx) {
+ $self->send(pc85($main::mycall, $fromnode, $user, "$main::mycall:$line"));
+ } else {
+ $self->send(pc35($main::mycall, $fromnode, "$main::mycall:$line"));
+ }
+ }
+}
+
+# Punt off a long running command into a separate process - this will be caused by an rcmd from outside
+#
+# This is called from commands to run some potentially long running
+# function. The process forks and then runs the function and returns
+# the result back to the cmd.
+#
+# NOTE: this merely forks the current process and then runs the cmd in that (current) context.
+# IT DOES NOT START UP SOME NEW PROGRAM AND RELIES ON THE FACT THAT IT IS RUNNING DXSPIDER
+# THE CURRENT CONTEXT!!
+#
+# call: $self->spawn_cmd($original_cmd_line, \<function>, [cb => sub{...}], [prefix => "cmd> "], [progress => 0|1], [args => [...]]);
+sub spawn_cmd
+{
+ my $self = shift;
+ my $line = shift;
+ my $cmdref = shift;
+ my $call = $self->{call};
+ my %args = @_;
+ my @out;
+
+ my $cb = delete $args{cb};
+ my $prefix = delete $args{prefix};
+ my $progress = delete $args{progress};
+ my $args = delete $args{args} || [];
+ my $t0 = [gettimeofday];
+
+ # remembered from process_cmd when spawn_cmd was called thru DXCommandmode::run_cmd which was called by process_rcmd
+ my $fromnode = $self->{_rcmd_fromnode};
+ my $user = $self->{_rcmd_user};
+
+ no strict 'refs';
+
+ my $fc = DXSubprocess->new;
+
+ # just behave normally if something has set the "one-shot" _nospawn in the channel
+ if ($self->{_nospawn}) {
+ eval { @out = $cmdref->(@$args); };
+ if ($@) {
+ DXDebug::dbgprintring(25);
+ push @out, DXDebug::shortmess($@);
+ }
+ return @out;
+ }
+
+ # $fc->serializer(\&encode_json);
+# $fc->deserializer(\&decode_json);
+ $fc->run(
+ sub {
+ my $subpro = shift;
+ if (isdbg('progress')) {
+ my $s = qq{line: "$line"};
+ $s .= ", args: " . join(', ', map { defined $_ ? qq{'$_'} : q{'undef'} } @$args) if $args && @$args;
+ dbg($s);
+ }
+ eval { @out = $cmdref->(@$args); };
+ if ($@) {
+ DXDebug::dbgprintring(25);
+ push @out, DXDebug::shortmess($@);
+ }
+ return @out;
+ },
+# $args,
+ sub {
+ my ($fc, $err, @res) = @_;
+ my $self = DXChannel::get($call);
+ return unless $self;
+
+ if ($err) {
+ my $s = "DXCommand::spawn_cmd: call $call error $err";
+ dbg($s) if isdbg('chan');
+ if ($fromnode && $user) {
+ $self->send_rcmd_reply($main::mycall, $fromnode, $user, $s);
+ } else {
+ $self->send($s);
+ }
+ return;
+ }
+ if ($cb) {
+ # transform output if required
+ @res = $cb->($self, @res);
+ }
+ if (@res) {
+ if ($fromnode && $user) {
+ $self->send_rcmd_reply($main::mycall, $fromnode, $user, @res);
+ } else {
+ $self->send(@res);
+ }
+ }
+ diffms("rcmd from $user on $call", $line, $t0, scalar @res) if isdbg('progress');
+ });
+
+ return @out;
+}
+
+sub process_rcmd_reply
+{
+ my ($self, $tonode, $fromnode, $user, $line) = @_;
+ if ($tonode eq $main::mycall) {
+ my $s = $rcmds{$fromnode};
+ if ($s) {
+ my $dxchan = DXChannel::get($s->{call});
+ my $ref = $user eq $tonode ? $dxchan : (DXChannel::get($user) || $dxchan);
+ $ref->send($line) if $ref;
+ delete $rcmds{$fromnode} if !$dxchan;
+ } else {
+ # send unsolicited ones to the sysop
+ my $dxchan = DXChannel::get($main::myalias);
+ $dxchan->send($line) if $dxchan;
+ }
+ } else {
+ my $ref = DXUser::get_current($tonode);
+ if ($ref && $ref->is_clx) {
+ $self->route($tonode, pc85($fromnode, $tonode, $user, $line));
+ } else {
+ $self->route($tonode, pc35($fromnode, $tonode, $line));
+ }
+ }
+}
+
+
+
+# add a rcmd request to the rcmd queues
+sub addrcmd
+{
+ my ($self, $to, $cmd) = @_;
+
+ my $r = {};
+ $r->{call} = $self->{call};
+ $r->{t} = $main::systime;
+ $r->{cmd} = $cmd;
+ $rcmds{$to} = $r;
+
+ my $ref = Route::Node::get($to);
+ my $dxchan = $ref->dxchan;
+ if ($dxchan && $dxchan->is_clx) {
+ route(undef, $to, pc84($main::mycall, $to, $self->{call}, $cmd));
+ } else {
+ route(undef, $to, pc34($main::mycall, $to, $cmd));
+ }
+}
+
+sub disconnect
+{
+ my $self = shift;
+ my $pc39flag = shift || 0;
+ my $call = $self->call;
+
+ return if $self->{disconnecting}++;
+
+ unless ($pc39flag == 1) {
+ $self->send_now("D", DXProt::pc39($main::mycall, $self->msg('disc1', "System Op")));
+ }
+
+ # get rid of any PC16/17/19
+ eph_del_regex("^PC1[679]*$call");
+
+ # do routing stuff, remove me from routing table
+ my $node = Route::Node::get($call);
+
+ Route::delete_interface($call);
+
+ # unbusy and stop and outgoing mail
+ my $mref = DXMsg::get_busy($call);
+ $mref->stop_msg($call) if $mref;
+
+ # remove outstanding pings
+ delete $pings{$call};
+
+ # I was the last node visited
+ $self->user->node($main::mycall);
+
+ # send info to all logged in thingies
+ $self->tell_login('logoutn');
+
+ Log('DXProt', $call . " Disconnected");
+
+ $self->SUPER::disconnect;
+
+ # here we determine what needs to go out of the routing table
+ my @rout;
+ if ($node && $pc39flag != 2) {
+ dbg('%Route::Node::List = ' . join(',', sort keys %Route::Node::list)) if isdbg('routedisc');
+
+ @rout = $node->del($main::routeroot);
+
+ dbg('@rout = ' . join(',', sort map {$_->call} @rout)) if isdbg('routedisc');
+
+ # now we need to see what can't be routed anymore and came
+ # in via this node (probably).
+ my $n = 0;
+ while ($n != @rout) {
+ $n = @rout;
+ for (Route::Node::get_all()) {
+ unless ($_->dxchan) {
+ push @rout, $_->delete;
+ }
+ }
+ dbg('@rout = ' . join(',', sort map {$_->call} @rout)) if isdbg('routedisc');
+ }
+
+ dbg('%Route::Node::List = ' . join(',', sort keys %Route::Node::list)) if isdbg('routedisc');
+
+ # and all my ephemera as well
+ for (@rout) {
+ my $c = $_->call;
+ eph_del_regex("^PC1[679].*$c");
+ }
+ }
+
+ # broadcast to all other nodes that all the nodes connected to via me are gone
+ unless ($pc39flag == 2) {
+ $self->route_pc21($main::mycall, undef, @rout) if @rout;
+ $self->route_pc92d($main::mycall, undef, $main::routeroot, $node) if $node;
+ }
+}
+
+
+#
+# send a talk message to this thingy
+#
+sub talk
+{
+ my ($self, $from, $to, $via, $line, $origin) = @_;
+
+ if ($self->{do_pc9x}) {
+ $self->send(pc93($to, $from, $via, $line));
+ } else {
+ $self->send(pc10($from, $to, $via, $line, $origin));
+ }
+ Log('talk', $to, $from, '>' . ($via || $origin || $self->call), $line) unless $origin && $origin ne $main::mycall;
+}
+
+# send it if it isn't the except list and isn't isolated and still has a hop count
+# taking into account filtering and so on
+
+sub send_route
+{
+ my $self = shift;
+ my $origin = shift;
+ my $generate = shift;
+ my $no = shift; # the no of things to filter on
+ my $routeit;
+ my ($filter, $hops);
+ my @rin;
+
+ for (; @_ && $no; $no--) {
+ my $r = shift;
+
+ # don't send messages with $self's call in back to them
+ if ($r->call eq $self->{call}) {
+ dbg("PCPROT: trying to send $self->{call} back itself") if isdbg('chanerr');
+ next;
+ }
+
+ if (!$self->{isolate} && $self->{routefilter}) {
+ $filter = undef;
+ if ($r) {
+ ($filter, $hops) = $self->{routefilter}->it($self->{call}, $self->{dxcc}, $self->{itu}, $self->{cq}, $r->call, $r->dxcc, $r->itu, $r->cq, $self->{state}, $r->{state});
+ if ($filter) {
+ push @rin, $r;
+ } else {
+ dbg("PCPROT: $self->{call}/" . $r->call . " rejected by output filter") if isdbg('filter');
+ }
+ } else {
+ dbg("was sent a null value") if isdbg('chanerr');
+ }
+ } else {
+ push @rin, $r unless $self->{isolate} && $r->call ne $main::mycall;
+ }
+ }
+ if (@rin) {
+ foreach my $line (&$generate(@rin, @_)) {
+ if ($hops) {
+ $routeit = $line;
+ $routeit =~ s/\^H\d+\^\~$/\^H$hops\^\~/;
+ } else {
+ $routeit = adjust_hops($self, $line); # adjust its hop count by node name
+ next unless $routeit;
+ }
+
+ $self->send($routeit);
+ }
+ }
+}
+
+# broadcast everywhere
+sub broadcast_route
+{
+ my $self = shift;
+ my $origin = shift;
+ my $generate = shift;
+ my $line = shift;
+ my @dxchan = DXChannel::get_all_nodes();
+ my $dxchan;
+
+ if ($line) {
+ $line =~ /\^H(\d+)\^?\~?$/;
+ return unless $1 > 0;
+ }
+ unless ($self->{isolate}) {
+ foreach $dxchan (@dxchan) {
+ next if $dxchan == $self || $dxchan == $main::me;
+ next if $origin eq $dxchan->{call}; # don't route some from this call back again.
+ next unless $dxchan->isa('DXProt');
+
+ $dxchan->send_route($origin, $generate, @_);
+ }
+ }
+}
+
+# broadcast to non-pc9x nodes
+sub broadcast_route_nopc9x
+{
+ my $self = shift;
+ my $origin = shift;
+ my $generate = shift;
+ my $line = shift;
+ my @dxchan = DXChannel::get_all_nodes();
+ my $dxchan;
+
+ if ($line) {
+ $line =~ /\^H(\d+)\^?\~?$/;
+ return unless $1 > 0;
+ }
+ unless ($self->{isolate}) {
+ foreach $dxchan (@dxchan) {
+ next if $dxchan == $self || $dxchan == $main::me;
+ next if $origin eq $dxchan->{call}; # don't route some from this call back again.
+ next unless $dxchan->isa('DXProt');
+ next if $dxchan->{do_pc9x};
+ if ($generate == \&pc16 || $generate==\&pc17) {
+ next unless $dxchan->user->wantsendpc16;
+ }
+ $dxchan->send_route($origin, $generate, @_);
+ }
+ }
+}
+
+# this is only used for next door nodes on init
+sub send_route_pc92
+{
+ my $self = shift;
+
+ return unless $self->{do_pc9x};
+
+ my $origin = shift;
+ my $generate = shift;
+ my $no = shift; # the no of things to filter on
+ my $line;
+
+ $line = &$generate(@_);
+ $self->send($line);
+}
+
+# broadcast only to pc9x nodes
+sub broadcast_route_pc9x
+{
+ my $self = shift;
+ my $origin = shift;
+ my $generate = shift;
+ my $line = shift;
+ my $no = shift;
+ my @dxchan = DXChannel::get_all_nodes();
+ my $dxchan;
+
+ if ($origin eq $main::mycall && $generate && !$line) {
+ $line = &$generate(@_);
+ }
+
+ $line =~ /\^H(\d+)\^\~?$/;
+ unless ($1 > 0 && $self->{isolate}) {
+ foreach $dxchan (@dxchan) {
+ next if $dxchan == $self || $dxchan == $main::me;
+ next if $origin eq $dxchan->{call}; # don't route some from this call back again.
+ next unless $dxchan->isa('DXProt');
+ next unless $dxchan->{do_pc9x};
+
+ $dxchan->send($line);
+ }
+ }
+}
+
+sub route_pc16
+{
+ my $self = shift;
+ return unless $self->user->wantpc16;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route_nopc9x($self, $origin, \&pc16, $line, 1, @_);
+}
+
+sub route_pc17
+{
+ my $self = shift;
+ return unless $self->user->wantpc16;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route_nopc9x($self, $origin, \&pc17, $line, 1, @_);
+}
+
+sub route_pc19
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route_nopc9x($self, $origin, \&pc19, $line, scalar @_, @_);
+}
+
+sub route_pc21
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route_nopc9x($self, $origin, \&pc21, $line, scalar @_, @_);
+}
+
+sub route_pc24
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route($self, $origin, \&pc24, $line, 1, @_);
+}
+
+sub route_pc41
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route($self, $origin, \&pc41, $line, 1, @_);
+}
+
+# this is probably obsolete now
+sub route_pc50
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+
+ broadcast_route($self, $origin, \&pc50, $line, 1, @_);
+}
+
+sub route_pc92c
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route_pc9x($self, $origin, \&pc92c, $line, 1, @_);
+}
+
+sub route_pc92a
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route_pc9x($self, $origin, \&pc92a, $line, 1, @_);
+}
+
+sub route_pc92d
+{
+ my $self = shift;
+ my $origin = shift;
+ my $line = shift;
+ broadcast_route_pc9x($self, $origin, \&pc92d, $line, 1, @_);
+}