perl/convkeps.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # Convert an Amsat 2 line keps bull into Sun.pm format
   4 #
   5 # This program will accept on stdin a standard AMSAT 2 line keps
   6 # bull such as you would find in an email or from the packet network
   7 #
   8 # It will write a file called /spider/local/Keps.pm, this means that
   9 # the latest version will be read in every time you restart the
  10 # cluster.pl. You can also call Sun::load from a cron line if
  11 # you like to re-read it automatically. If you update it manually
  12 # load/keps will load the latest version into the cluster
  13 #
  14 # This program is designed to be called from /etc/aliases or
  15 # a .forward file so you can get yourself on the keps mailing
  16 # list from AMSAT and have the keps updated automatically once
  17 # a week.
  18 #
  19 # I will distribute the latest keps with every patch but you can
  20 # get your own data from:
  21 #
  22 # http://www.amsat.org/amsat/ftp/keps/current/nasa.all
  23 #
  24 # Please note that this will UPDATE your keps file
  25 #
  26 # Usage:
  27 #    email | convkeps.pl        (in amsat email format)
  28 #    convkeps.pl -p keps.in     (a file with just plain keps)
  29 #
  30 # if you add the -c flag then the %keps hash will be cleared down
  31 # before adding the new ones.
  32 #
  33 # Copyright (c) 2000 Dirk Koopman G1TLH
  34 #
  35 # $Id$
  36 #
  37
  38 require 5.004;
  39 package Sun;
  40
  41 # search local then perl directories
  42 BEGIN {
  43         # root of directory tree for this system
  44         $root = "/spider";
  45         $root = $ENV{'DXSPIDER_ROOT'} if $ENV{'DXSPIDER_ROOT'};
  46
  47         unshift @INC, "$root/perl";     # this IS the right way round!
  48         unshift @INC, "$root/local";
  49 }
  50
  51 use strict;
  52 use vars qw($root %keps);
  53
  54 use Data::Dumper;
  55 require Keps;
  56
  57 my $fn = "$root/local/Keps.pm";
  58 my $state = 0;
  59 my $name;
  60 my $ref;
  61 my $line;
  62 my $count = 0;
  63
  64 my $f = \*STDIN;
  65
  66 while (@ARGV) {
  67         my $arg = shift @ARGV;
  68         if ($arg eq '-p') {
  69                 $state = 1;
  70         } elsif ($arg eq '-e') {
  71                 $state = 0;
  72         } elsif ($arg eq '-c') {
  73                 %keps = ();
  74         } elsif ($arg =~ /^-/) {
  75                 die "Usage: convkeps.pl [-c] [-e|-p] [<filename>]\n\t-p - plain file just containing keps\n\t-e - amsat email format input file (default)\n\t-c - clear Keps data before adding this lot\n";
  76         } else {
  77                 open (IN, $arg) or die "cannot open $arg (!$)";
  78                 $f = \*IN;
  79         }
  80 }
  81
  82 while (<$f>) {
  83         ++$line;
  84 #    print;
  85         chomp;
  86         last if m{^-};
  87
  88         s/^\s+//;
  89     s/[\s\r]+$//;
  90         next unless $_;
  91         last if m{^/EX}i;
  92
  93         if ($state == 0 && /^Decode/i) {
  94                 $state = 1;
  95         } elsif ($state == 1) {
  96                 last if m{^-};
  97                 next if m{^To\s+all}i;
  98
  99                 if (/^[- \w]+$/) {
 100                         s/\s/-/g;
 101                         $name = uc $_;
 102                         $ref = $keps{$name} = {};
 103                         $state = 2;
 104                 }
 105         } elsif ($state == 2) {
 106                 if (/^1 /) {
 107                         my ($id, $number, $epoch, $decay, $mm2, $bstar, $elset) = unpack "xxa5xxa5xxxa15xa10xa8xa8xxxa4x", $_;
 108                         $ref->{id} = $id - 0;
 109                         $ref->{number} = $number - 0;
 110                         $ref->{epoch} = $epoch - 0;
 111                         $ref->{mm1} = $decay - 0;
 112                         $ref->{mm2} = genenum($mm2);
 113                         $ref->{bstar} = genenum($bstar);
 114                         $ref->{elset} = $elset - 0;
 115                         #print "$id $number $epoch $decay $mm2 $bstar $elset\n";
 116                         #print "mm2: $ref->{mm2} bstar: $ref->{bstar}\n";
 117
 118                         $state = 3;
 119                 } else {
 120                         #print "out of order on line $line\n";
 121                         undef $ref;
 122                         delete $keps{$name};
 123                         $state = 1;
 124                 }
 125         } elsif ($state == 3) {
 126                 if (/^2 /) {
 127                         my ($id, $incl, $raan, $ecc, $peri, $man, $mmo, $orbit) = unpack "xxa5xa8xa8xa7xa8xa8xa11a5x", $_;
 128                         $ref->{meananomaly} = $man - 0;
 129                         $ref->{meanmotion} = $mmo - 0;
 130                         $ref->{inclination} = $incl - 0;
 131                         $ref->{eccentricity} = ".$ecc" - 0;
 132                         $ref->{argperigee} = $peri - 0;
 133                         $ref->{raan} = $raan - 0;
 134                         $ref->{orbit} = $orbit - 0;
 135                         $count++;
 136                 } else {
 137                         #print "out of order on line $line\n";
 138                         delete $keps{$name};
 139                 }
 140                 undef $ref;
 141                 $state = 1;
 142         }
 143 }
 144
 145 if ($count) {
 146         my $dd = new Data::Dumper([\%keps], [qw(*keps)]);
 147         $dd->Indent(1);
 148         $dd->Quotekeys(0);
 149         open(OUT, ">$fn") or die "$fn $!";
 150         print OUT "#\n# this file is automatically produced by convkeps.pl\n#\n";
 151         print OUT "# Last update: ", scalar gmtime, "\n#\n";
 152         print OUT "\npackage Sun;\n\n";
 153         print OUT $dd->Dumpxs;
 154         print OUT "1;\n";
 155         close(OUT);
 156 }
 157
 158 print "$count keps converted\n";
 159 exit($count ? 0 : -1);
 160
 161
 162 # convert (+/-)00000-0 to (+/-).00000e-0
 163 sub genenum
 164 {
 165         my ($sign, $frac, $esign, $exp) = unpack "aa5aa", shift;
 166         $esign = '+' if $esign eq ' ';
 167         my $n = $sign . "." . $frac . 'e' . $esign . $exp;
 168         return $n - 0;
 169 }
 170