perl/DXUtil.pm

   1 #
   2 # various utilities which are exported globally
   3 #
   4 # Copyright (c) 1998 - Dirk Koopman G1TLH
   5 #
   6 # $Id$
   7 #
   8
   9 package DXUtil;
  10
  11 use Date::Parse;
  12 use IO::File;
  13 use File::Copy;
  14 use Data::Dumper;
  15
  16 use strict;
  17
  18 use vars qw($VERSION $BRANCH);
  19 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  20 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  21 $main::build += $VERSION;
  22 $main::branch += $BRANCH;
  23
  24 use vars qw(@month %patmap @ISA @EXPORT);
  25
  26 require Exporter;
  27 @ISA = qw(Exporter);
  28 @EXPORT = qw(atime ztime cldate cldatetime slat slong yesno promptf
  29                          parray parraypairs phex shellregex readfilestr writefilestr
  30                          filecopy
  31              print_all_fields cltounix unpad is_callsign is_latlong
  32                          is_qra is_freq is_digits is_pctext is_pcflag insertitem deleteitem
  33             );
  34
  35
  36 @month = qw(Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec);
  37 %patmap = (
  38                    '*' => '.*',
  39                    '?' => '.',
  40                    '[' => '[',
  41                    ']' => ']'
  42 );
  43
  44 # a full time for logging and other purposes
  45 sub atime
  46 {
  47         my $t = shift;
  48         my ($sec,$min,$hour,$mday,$mon,$year) = gmtime((defined $t) ? $t : time);
  49         $year += 1900;
  50         my $buf = sprintf "%02d%s%04d\@%02d:%02d:%02d", $mday, $month[$mon], $year, $hour, $min, $sec;
  51         return $buf;
  52 }
  53
  54 # get a zulu time in cluster format (2300Z)
  55 sub ztime
  56 {
  57         my $t = shift;
  58         $t = defined $t ? $t : time;
  59         my $dst = shift;
  60         my ($sec,$min,$hour) = $dst ? localtime($t): gmtime($t);
  61         my $buf = sprintf "%02d%02d%s", $hour, $min, ($dst) ? '' : 'Z';
  62         return $buf;
  63 }
  64
  65 # get a cluster format date (23-Jun-1998)
  66 sub cldate
  67 {
  68         my $t = shift;
  69         $t = defined $t ? $t : time;
  70         my $dst = shift;
  71         my ($sec,$min,$hour,$mday,$mon,$year) = $dst ? localtime($t) : gmtime($t);
  72         $year += 1900;
  73         my $buf = sprintf "%2d-%s-%04d", $mday, $month[$mon], $year;
  74         return $buf;
  75 }
  76
  77 # return a cluster style date time
  78 sub cldatetime
  79 {
  80         my $t = shift;
  81         my $dst = shift;
  82         my $date = cldate($t, $dst);
  83         my $time = ztime($t, $dst);
  84         return "$date $time";
  85 }
  86
  87 # return a unix date from a cluster date and time
  88 sub cltounix
  89 {
  90         my $date = shift;
  91         my $time = shift;
  92         my ($thisyear) = (gmtime)[5] + 1900;
  93
  94         return 0 unless $date =~ /^\s*(\d+)-(\w\w\w)-([12][90]\d\d)$/;
  95         return 0 if $3 > 2036;
  96         return 0 unless abs($thisyear-$3) <= 1;
  97         $date = "$1 $2 $3";
  98         return 0 unless $time =~ /^([012]\d)([012345]\d)Z$/;
  99         $time = "$1:$2 +0000";
 100         my $r = str2time("$date $time");
 101         return $r unless $r;
 102         return $r == -1 ? undef : $r;
 103 }
 104
 105 # turn a latitude in degrees into a string
 106 sub slat
 107 {
 108         my $n = shift;
 109         my ($deg, $min, $let);
 110         $let = $n >= 0 ? 'N' : 'S';
 111         $n = abs $n;
 112         $deg = int $n;
 113         $min = int ((($n - $deg) * 60) + 0.5);
 114         return "$deg $min $let";
 115 }
 116
 117 # turn a longitude in degrees into a string
 118 sub slong
 119 {
 120         my $n = shift;
 121         my ($deg, $min, $let);
 122         $let = $n >= 0 ? 'E' : 'W';
 123         $n = abs $n;
 124         $deg = int $n;
 125         $min = int ((($n - $deg) * 60) + 0.5);
 126         return "$deg $min $let";
 127 }
 128
 129 # turn a true into 'yes' and false into 'no'
 130 sub yesno
 131 {
 132         my $n = shift;
 133         return $n ? $main::yes : $main::no;
 134 }
 135
 136 # format a prompt with its current value and return it with its privilege
 137 sub promptf
 138 {
 139         my ($line, $value) = @_;
 140         my ($priv, $prompt, $action) = split ',', $line;
 141
 142         # if there is an action treat it as a subroutine and replace $value
 143         if ($action) {
 144                 my $q = qq{\$value = $action(\$value)};
 145                 eval $q;
 146         } elsif (ref $value) {
 147                 my $dd = new Data::Dumper([$value]);
 148                 $dd->Indent(0);
 149                 $dd->Terse(1);
 150                 $dd->Quotekeys(0);
 151                 $value = $dd->Dumpxs;
 152                 $value =~ s/([\r\n\t])/sprintf("%%%02X", ord($1))/eg;
 153         }
 154         $prompt = sprintf "%15s: %s", $prompt, $value;
 155         return ($priv, $prompt);
 156 }
 157
 158 # turn a hex field into printed hex
 159 sub phex
 160 {
 161         my $val = shift;
 162         return sprintf '%X', $val;
 163 }
 164
 165 # take an arg as an array list and print it
 166 sub parray
 167 {
 168         my $ref = shift;
 169         return ref $ref ? join(', ', @{$ref}) : $ref;
 170 }
 171
 172 # take the arg as an array reference and print as a list of pairs
 173 sub parraypairs
 174 {
 175         my $ref = shift;
 176         my $i;
 177         my $out;
 178
 179         for ($i = 0; $i < @$ref; $i += 2) {
 180                 my $r1 = @$ref[$i];
 181                 my $r2 = @$ref[$i+1];
 182                 $out .= "$r1-$r2, ";
 183         }
 184         chop $out;                                      # remove last space
 185         chop $out;                                      # remove last comma
 186         return $out;
 187 }
 188
 189 sub _sort_fields
 190 {
 191         my $ref = shift;
 192         my @a = split /,/, $ref->field_prompt(shift);
 193         my @b = split /,/, $ref->field_prompt(shift);
 194         return lc $a[1] cmp lc $b[1];
 195 }
 196
 197 # print all the fields for a record according to privilege
 198 #
 199 # The prompt record is of the format '<priv>,<prompt>[,<action>'
 200 # and is expanded by promptf above
 201 #
 202 sub print_all_fields
 203 {
 204         my $self = shift;                       # is a dxchan
 205         my $ref = shift;                        # is a thingy with field_prompt and fields methods defined
 206         my @out;
 207         my @fields = $ref->fields;
 208         my $field;
 209         my $width = $self->width - 1;
 210         $width ||= 80;
 211
 212         foreach $field (sort {_sort_fields($ref, $a, $b)} @fields) {
 213                 if (defined $ref->{$field}) {
 214                         my ($priv, $ans) = promptf($ref->field_prompt($field), $ref->{$field});
 215                         my @tmp;
 216                         if (length $ans > $width) {
 217                                 my ($p, $a) = split /: /, $ans, 2;
 218                                 my $l = (length $p) + 2;
 219                                 my $al = ($width - 1) - $l;
 220                                 my $bit;
 221                                 while (length $a > $al ) {
 222                                         ($bit, $a) = unpack "A$al A*", $a;
 223                                         push @tmp, "$p: $bit";
 224                                         $p = ' ' x ($l - 2);
 225                                 }
 226                                 push @tmp, "$p: $a" if length $a;
 227                         } else {
 228                                 push @tmp, $ans;
 229                         }
 230                         push @out, @tmp if ($self->priv >= $priv);
 231                 }
 232         }
 233         return @out;
 234 }
 235
 236 # generate a regex from a shell type expression
 237 # see 'perl cookbook' 6.9
 238 sub shellregex
 239 {
 240         my $in = shift;
 241         $in =~ s{(.)} { $patmap{$1} || "\Q$1" }ge;
 242         return '^' . $in . "\$";
 243 }
 244
 245 # read in a file into a string and return it.
 246 # the filename can be split into a dir and file and the
 247 # file can be in upper or lower case.
 248 # there can also be a suffix
 249 sub readfilestr
 250 {
 251         my ($dir, $file, $suffix) = @_;
 252         my $fn;
 253         my $f;
 254         if ($suffix) {
 255                 $f = uc $file;
 256                 $fn = "$dir/$f.$suffix";
 257                 unless (-e $fn) {
 258                         $f = lc $file;
 259                         $fn = "$dir/$file.$suffix";
 260                 }
 261         } elsif ($file) {
 262                 $f = uc $file;
 263                 $fn = "$dir/$file";
 264                 unless (-e $fn) {
 265                         $f = lc $file;
 266                         $fn = "$dir/$file";
 267                 }
 268         } else {
 269                 $fn = $dir;
 270         }
 271
 272         my $fh = new IO::File $fn;
 273         my $s = undef;
 274         if ($fh) {
 275                 local $/ = undef;
 276                 $s = <$fh>;
 277                 $fh->close;
 278         }
 279         return $s;
 280 }
 281
 282 # write out a file in the format required for reading
 283 # in via readfilestr, it expects the same arguments
 284 # and a reference to an object
 285 sub writefilestr
 286 {
 287         my $dir = shift;
 288         my $file = shift;
 289         my $suffix = shift;
 290         my $obj = shift;
 291         my $fn;
 292         my $f;
 293
 294         confess('no object to write in writefilestr') unless $obj;
 295         confess('object not a reference in writefilestr') unless ref $obj;
 296
 297         if ($suffix) {
 298                 $f = uc $file;
 299                 $fn = "$dir/$f.$suffix";
 300                 unless (-e $fn) {
 301                         $f = lc $file;
 302                         $fn = "$dir/$file.$suffix";
 303                 }
 304         } elsif ($file) {
 305                 $f = uc $file;
 306                 $fn = "$dir/$file";
 307                 unless (-e $fn) {
 308                         $f = lc $file;
 309                         $fn = "$dir/$file";
 310                 }
 311         } else {
 312                 $fn = $dir;
 313         }
 314
 315         my $fh = new IO::File ">$fn";
 316         if ($fh) {
 317                 my $dd = new Data::Dumper([ $obj ]);
 318                 $dd->Indent(1);
 319                 $dd->Terse(1);
 320                 $dd->Quotekeys(0);
 321                 #       $fh->print(@_) if @_ > 0;     # any header comments, lines etc
 322                 $fh->print($dd->Dumpxs);
 323                 $fh->close;
 324         }
 325 }
 326
 327 sub filecopy
 328 {
 329         copy(@_) or return $!;
 330 }
 331
 332 # remove leading and trailing spaces from an input string
 333 sub unpad
 334 {
 335         my $s = shift;
 336         $s =~ s/\s+$//;
 337         $s =~ s/^\s+//;
 338         return $s;
 339 }
 340
 341 # check that a field only has callsign characters in it
 342 sub is_callsign
 343 {
 344         return $_[0] =~ /^(?:[A-Z]{1,2}\d+|\d[A-Z]{1,2}\d+)[A-Z]{1,3}(?:-\d{1,2}|\/(?:[A-Z]{1,2}\d{0,2}|\d[A-Z]\d{0,2}))?$/;
 345 }
 346
 347 # check that a PC protocol field is valid text
 348 sub is_pctext
 349 {
 350         return undef unless length $_[0];
 351         return undef if $_[0] =~ /[\x00-\x08\x0a-\x1f\x80-\x9f]/;
 352         return 1;
 353 }
 354
 355 # check that a PC prot flag is fairly valid (doesn't check the difference between 1/0 and */-)
 356 sub is_pcflag
 357 {
 358         return $_[0] =~ /^[01\*\-]+$/;
 359 }
 360
 361 # check that a thing is a frequency
 362 sub is_freq
 363 {
 364         return $_[0] =~ /^\d+(?:\.\d+)?$/;
 365 }
 366
 367 # check that a thing is just digits
 368 sub is_digits
 369 {
 370         return $_[0] =~ /^[\d]+$/;
 371 }
 372
 373 # does it look like a qra locator?
 374 sub is_qra
 375 {
 376         return $_[0] =~ /^[A-Ra-r][A-Ra-r]\d\d[A-Xa-x][A-Xa-x]$/;
 377 }
 378
 379 # does it look like a valid lat/long
 380 sub is_latlong
 381 {
 382         return $_[0] =~ /^\s*\d{1,2}\s+\d{1,2}\s*[NnSs]\s+1?\d{1,2}\s+\d{1,2}\s*[EeWw]\s*$/;
 383 }
 384
 385 # insert an item into a list if it isn't already there returns 1 if there 0 if not
 386 sub insertitem
 387 {
 388         my $list = shift;
 389         my $item = shift;
 390
 391         return 1 if grep {$_ eq $item } @$list;
 392         push @$list, $item;
 393         return 0;
 394 }
 395
 396 # delete an item from a list if it is there returns no deleted
 397 sub deleteitem
 398 {
 399         my $list = shift;
 400         my $item = shift;
 401         my $n = @$list;
 402
 403         @$list = grep {$_ ne $item } @$list;
 404         return $n - @$list;
 405 }