perl/DXSql.pm

   1 #
   2 # The master SQL module
   3 #
   4 # $Id$
   5 #
   6 # Copyright (c) 2006 Dirk Koopman G1TLH
   7 #
   8
   9 package DXSql;
  10
  11 use strict;
  12
  13 use DXDebug;
  14
  15 use vars qw($VERSION $BRANCH);
  16 $VERSION = sprintf( "%d.%03d", q$Revision$ =~ /(\d+)\.(\d+)/ );
  17 $BRANCH = sprintf( "%d.%03d", q$Revision$ =~ /\d+\.\d+\.(\d+)\.(\d+)/  || (0,0));
  18 $main::build += $VERSION;
  19 $main::branch += $BRANCH;
  20
  21 our $active = 0;
  22
  23 sub init
  24 {
  25         return $active if $active;
  26
  27         eval {
  28                 require DBI;
  29         };
  30         unless ($@) {
  31                 import DBI;
  32                 $active++;
  33         }
  34         undef $@;
  35         return $active;
  36 }
  37
  38 sub new
  39 {
  40         my $class = shift;
  41         my $dsn = shift;
  42         my $self;
  43
  44         return undef unless $active;
  45         my $dbh;
  46         my ($style) = $dsn =~ /^dbi:(\w+):/;
  47         my $newclass = "DXSql::$style";
  48         eval "require $newclass";
  49         if ($@) {
  50                 $active = 0;
  51                 return undef;
  52         }
  53         return bless {}, $newclass;
  54 }
  55
  56 sub connect
  57 {
  58         my $self = shift;
  59         my $dsn = shift;
  60         my $user = shift;
  61         my $passwd = shift;
  62
  63         my $dbh;
  64         eval {
  65                 no strict 'refs';
  66                 $dbh = DBI->connect($dsn, $user, $passwd, {AutoCommit => 0});
  67         };
  68         unless ($dbh) {
  69                 $active = 0;
  70                 return undef;
  71         }
  72         $self->{dbh} = $dbh;
  73         return $self;
  74 }
  75
  76 sub finish
  77 {
  78         my $self = shift;
  79         $self->{dbh}->disconnect;
  80 }
  81
  82 sub do
  83 {
  84         my $self = shift;
  85         my $s = shift;
  86
  87         eval { $self->{dbh}->do($s); };
  88 }
  89
  90 sub commit
  91 {
  92         $_[0]->{dbh}->commit;
  93         $_[0]->{dbh}->{AutoCommit} = 0;
  94 }
  95
  96 sub rollback
  97 {
  98         $_[0]->{dbh}->rollback;
  99         $_[0]->{dbh}->{AutoCommit} = 0;
 100 }
 101
 102 sub quote
 103 {
 104         return $_[0]->{dbh}->quote($_[1]);
 105 }
 106
 107 sub prepare
 108 {
 109         return $_[0]->{dbh}->prepare($_[1]);
 110 }
 111
 112 sub spot_insert_prepare
 113 {
 114         my $self = shift;
 115         return $self->prepare('insert into spot values(?' . ',?' x 14 . ')');
 116 }
 117
 118 sub spot_insert
 119 {
 120         my $self = shift;
 121         my $spot = shift;
 122         my $sth = shift;
 123
 124         if ($sth) {
 125                 eval {$sth->execute(undef, @$spot)};
 126         } else {
 127                 my $s = "insert into spot values(NULL,";
 128                 $s .= sprintf("%.1f,", $spot->[0]);
 129                 $s .= $self->quote($spot->[1]) . "," ;
 130                 $s .= $spot->[2] . ',';
 131                 $s .= (length $spot->[3] ? $self->quote($spot->[3]) : 'NULL') . ',';
 132                 $s .= $self->quote($spot->[4]) . ',';
 133                 $s .= $spot->[5] . ',';
 134                 $s .= $spot->[6] . ',';
 135                 $s .= (length $spot->[7] ? $self->quote($spot->[7]) : 'NULL') . ',';
 136                 $s .= $spot->[8] . ',';
 137                 $s .= $spot->[9] . ',';
 138                 $s .= $spot->[10] . ',';
 139                 $s .= $spot->[11] . ',';
 140                 $s .= (length $spot->[12] ? $self->quote($spot->[12]) : 'NULL') . ',';
 141                 $s .= (length $spot->[13] ? $self->quote($spot->[13]) : 'NULL') . ')';
 142                 eval {$self->do($s)};
 143         }
 144 }
 145
 146 sub spot_search
 147 {
 148         my $self = shift;
 149         my $expr = shift;
 150         my $dayfrom = shift;
 151         my $dayto = shift;
 152         my $n = shift;
 153         my $dxchan = shift;
 154
 155         dbg("expr: $expr") if isdbg('search');
 156         if ($expr =~ /\$f/) {
 157                 $expr =~ s/(?:==|eq)/ = /g;
 158                 $expr =~ s/\$f10/spotteritu/g;
 159                 $expr =~ s/\$f11/spottercq/g;
 160                 $expr =~ s/\$f12/spotstate/g;
 161                 $expr =~ s/\$f13/spotterstate/g;
 162                 $expr =~ s/\$f0/freq/g;
 163                 $expr =~ s/\$f1/spotcall/g;
 164                 $expr =~ s/\$f2/time/g;
 165                 $expr =~ s/\$f3/comment/g;
 166                 $expr =~ s/\$f4/spotter/g;
 167                 $expr =~ s/\$f5/spotdxcc/g;
 168                 $expr =~ s/\$f6/spotterdxcc/g;
 169                 $expr =~ s/\$f7/origin/g;
 170                 $expr =~ s/\$f8/spotitu/g;
 171                 $expr =~ s/\$f9/spotcq/g;
 172                 $expr =~ s/\|\|/ or /g;
 173                 $expr =~ s/\&\&/ and /g;
 174                 $expr =~ s/=~\s+m\{\^([%\w]+)[^\}]*\}/ like '$1'/g;
 175         } else {
 176                 $expr = '';
 177         }
 178         my $fdays = $dayfrom ? "time <= " . ($main::systime - ($dayfrom * 86400)) : "";
 179         my $days = "time >= " . ($main::systime - ($dayto * 86400));
 180         my $trange = $fdays ? "($fdays and $days)" : $days;
 181         $expr .= $expr ? " and $trange" : $trange;
 182     my $s = qq{select freq,spotcall,time,comment,spotter,spotdxcc,spotterdxcc,
 183 origin,spotitu,spotcq,spotteritu,spottercq,spotstate,spotterstate from spot
 184 where $expr order by time desc limit $n};
 185     dbg("sql expr: $s") if isdbg('search');
 186         my $ref = $self->{dbh}->selectall_arrayref($s);
 187         return @$ref;
 188 }
 189
 190 1;
 191