perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 # $Id$
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   inannfilter => '5,Ann Filt-inp',
  84                   inwwvfilter => '5,WWV Filt-inp',
  85                   inwcyfilter => '5,WCY Filt-inp',
  86                   inspotsfilter => '5,Spot Filt-inp',
  87                   inroutefilter => '5,Route Filt-inp',
  88                   passwd => '9,Passwd List,yesno',
  89                   pingint => '5,Ping Interval ',
  90                   nopings => '5,Ping Obs Count',
  91                   lastping => '5,Ping last sent,atime',
  92                   pingtime => '5,Ping totaltime,parray',
  93                   pingave => '0,Ping ave time',
  94                   logininfo => '9,Login info req,yesno',
  95                   talklist => '0,Talk List,parray',
  96                   cluster => '5,Cluster data',
  97                   isbasic => '9,Internal Connection',
  98                   errors => '9,Errors',
  99                   route => '9,Route Data',
 100                   dxcc => '0,Country Code',
 101                   itu => '0,ITU Zone',
 102                   cq => '0,CQ Zone',
 103                   enhanced => '5,Enhanced Client,yesno',
 104                   senddbg => '8,Sending Debug,yesno',
 105                   width => '0,Column Width',
 106                   disconnecting => '9,Disconnecting,yesno',
 107                   ann_talk => '0,Suppress Talk Anns,yesno',
 108                   metric => '1,Route metric',
 109                   badcount => '1,Bad Word Count',
 110                   edit => '7,Edit Function',
 111                   registered => '9,Registered?,yesno',
 112                   prompt => '0,Required Prompt',
 113                   version => '1,Node Version',
 114                   build => '1,Node Build',
 115                   verified => '9,Verified?,yesno',
 116                   newroute => '1,New Style Routing,yesno',
 117                   ve7cc => '0,VE7CC program special,yesno',
 118                   lastmsgpoll => '0,Last Msg Poll,atime',
 119                   inscript => '9,In a script,yesno',
 120                   inqueue => '9,Input Queue,parray',
 121                  );
 122
 123 use vars qw($VERSION $BRANCH);
 124
 125 main::mkver($VERSION = q$Revision$);
 126
 127 # object destruction
 128 sub DESTROY
 129 {
 130         my $self = shift;
 131         for (keys %$self) {
 132                 if (ref($self->{$_})) {
 133                         delete $self->{$_};
 134                 }
 135         }
 136         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 137         $count--;
 138 }
 139
 140 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 141 sub alloc
 142 {
 143         my ($pkg, $call, $conn, $user) = @_;
 144         my $self = {};
 145
 146         die "trying to create a duplicate channel for $call" if $channels{$call};
 147         $self->{call} = $call;
 148         $self->{priv} = 0;
 149         $self->{conn} = $conn if defined $conn; # if this isn't defined then it must be a list
 150         if (defined $user) {
 151                 $self->{user} = $user;
 152                 $self->{lang} = $user->lang;
 153                 $user->new_group() if !$user->group;
 154                 $self->{group} = $user->group;
 155                 $self->{sort} = $user->sort;
 156         }
 157         $self->{startt} = $self->{t} = time;
 158         $self->{state} = 0;
 159         $self->{oldstate} = 0;
 160         $self->{lang} = $main::lang if !$self->{lang};
 161         $self->{func} = "";
 162
 163         # add in all the dxcc, itu, zone info
 164         my @dxcc = Prefix::extract($call);
 165         if (@dxcc > 0) {
 166                 $self->{dxcc} = $dxcc[1]->dxcc;
 167                 $self->{itu} = $dxcc[1]->itu;
 168                 $self->{cq} = $dxcc[1]->cq;
 169         }
 170         $self->{inqueue} = [];
 171
 172         $count++;
 173         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 174         bless $self, $pkg;
 175         return $channels{$call} = $self;
 176 }
 177
 178 sub rec
 179 {
 180         my ($self, $msg) = @_;
 181
 182         # queue the message and the channel object for later processing
 183         if (defined $msg) {
 184                 push @{$self->{inqueue}}, $msg;
 185         }
 186 }
 187
 188 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 189 sub get
 190 {
 191         return $channels{$_[0]};
 192 }
 193
 194 # obtain all the channel objects
 195 sub get_all
 196 {
 197         return values(%channels);
 198 }
 199
 200 #
 201 # gimme all the ak1a nodes
 202 #
 203 sub get_all_nodes
 204 {
 205         my $ref;
 206         my @out;
 207         foreach $ref (values %channels) {
 208                 push @out, $ref if $ref->is_node;
 209         }
 210         return @out;
 211 }
 212
 213 # return a list of all users
 214 sub get_all_users
 215 {
 216         my $ref;
 217         my @out;
 218         foreach $ref (values %channels) {
 219                 push @out, $ref if $ref->is_user;
 220         }
 221         return @out;
 222 }
 223
 224 # return a list of all user callsigns
 225 sub get_all_user_calls
 226 {
 227         my $ref;
 228         my @out;
 229         foreach $ref (values %channels) {
 230                 push @out, $ref->{call} if $ref->is_user;
 231         }
 232         return @out;
 233 }
 234
 235 # obtain a channel object by searching for its connection reference
 236 sub get_by_cnum
 237 {
 238         my ($pkg, $conn) = @_;
 239         my $self;
 240
 241         foreach $self (values(%channels)) {
 242                 return $self if ($self->{conn} == $conn);
 243         }
 244         return undef;
 245 }
 246
 247 # get rid of a channel object [$obj->del()]
 248 sub del
 249 {
 250         my $self = shift;
 251
 252         $self->{group} = undef;         # belt and braces
 253         delete $channels{$self->{call}};
 254 }
 255
 256 # is it a bbs
 257 sub is_bbs
 258 {
 259         my $self = shift;
 260         return $self->{'sort'} eq 'B';
 261 }
 262
 263 sub is_node
 264 {
 265         my $self = shift;
 266         return $self->{'sort'} =~ /[ACRSX]/;
 267 }
 268 # is it an ak1a node ?
 269 sub is_ak1a
 270 {
 271         my $self = shift;
 272         return $self->{'sort'} eq 'A';
 273 }
 274
 275 # is it a user?
 276 sub is_user
 277 {
 278         my $self = shift;
 279         return $self->{'sort'} eq 'U';
 280 }
 281
 282 # is it a clx node
 283 sub is_clx
 284 {
 285         my $self = shift;
 286         return $self->{'sort'} eq 'C';
 287 }
 288
 289 # it is Aranea
 290 sub is_aranea
 291 {
 292         my $self = shift;
 293         return $self->{'sort'} eq 'W';
 294 }
 295
 296 # is it a spider node
 297 sub is_spider
 298 {
 299         my $self = shift;
 300         return $self->{'sort'} eq 'S';
 301 }
 302
 303 # is it a DXNet node
 304 sub is_dxnet
 305 {
 306         my $self = shift;
 307         return $self->{'sort'} eq 'X';
 308 }
 309
 310 # is it a ar-cluster node
 311 sub is_arcluster
 312 {
 313         my $self = shift;
 314         return $self->{'sort'} eq 'R';
 315 }
 316
 317 # for perl 5.004's benefit
 318 sub sort
 319 {
 320         my $self = shift;
 321         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 322 }
 323
 324 # find out whether we are prepared to believe this callsign on this interface
 325 sub is_believed
 326 {
 327         my $self = shift;
 328         my $call = shift;
 329
 330         return grep $call eq $_, $self->user->believe;
 331 }
 332
 333 # handle out going messages, immediately without waiting for the select to drop
 334 # this could, in theory, block
 335 sub send_now
 336 {
 337         my $self = shift;
 338         my $conn = $self->{conn};
 339         return unless $conn;
 340         my $sort = shift;
 341         my $call = $self->{call};
 342
 343         for (@_) {
 344 #               chomp;
 345         my @lines = split /\n/;
 346                 for (@lines) {
 347                         $conn->send_now("$sort$call|$_");
 348                         dbg("-> $sort $call $_") if isdbg('chan');
 349                 }
 350         }
 351         $self->{t} = time;
 352 }
 353
 354 #
 355 # send later with letter (more control)
 356 #
 357
 358 sub send_later
 359 {
 360         my $self = shift;
 361         my $conn = $self->{conn};
 362         return unless $conn;
 363         my $sort = shift;
 364         my $call = $self->{call};
 365
 366         for (@_) {
 367 #               chomp;
 368         my @lines = split /\n/;
 369                 for (@lines) {
 370                         $conn->send_later("$sort$call|$_");
 371                         dbg("-> $sort $call $_") if isdbg('chan');
 372                 }
 373         }
 374         $self->{t} = time;
 375 }
 376
 377 #
 378 # the normal output routine
 379 #
 380 sub send                                                # this is always later and always data
 381 {
 382         my $self = shift;
 383         my $conn = $self->{conn};
 384         return unless $conn;
 385         my $call = $self->{call};
 386
 387         for (@_) {
 388 #               chomp;
 389         my @lines = split /\n/;
 390                 for (@lines) {
 391                         $conn->send_later("D$call|$_");
 392                         dbg("-> D $call $_") if isdbg('chan');
 393                 }
 394         }
 395         $self->{t} = time;
 396 }
 397
 398 # send a file (always later)
 399 sub send_file
 400 {
 401         my ($self, $fn) = @_;
 402         my $call = $self->{call};
 403         my $conn = $self->{conn};
 404         my @buf;
 405
 406         open(F, $fn) or die "can't open $fn for sending file ($!)";
 407         @buf = <F>;
 408         close(F);
 409         $self->send(@buf);
 410 }
 411
 412 # this will implement language independence (in time)
 413 sub msg
 414 {
 415         my $self = shift;
 416         return DXM::msg($self->{lang}, @_);
 417 }
 418
 419 # stick a broadcast on the delayed queue (but only up to 20 items)
 420 sub delay
 421 {
 422         my $self = shift;
 423         my $s = shift;
 424
 425         $self->{delayed} = [] unless $self->{delayed};
 426         push @{$self->{delayed}}, $s;
 427         if (@{$self->{delayed}} >= 20) {
 428                 shift @{$self->{delayed}};   # lose oldest one
 429         }
 430 }
 431
 432 # change the state of the channel - lots of scope for debugging here :-)
 433 sub state
 434 {
 435         my $self = shift;
 436         if (@_) {
 437                 $self->{oldstate} = $self->{state};
 438                 $self->{state} = shift;
 439                 $self->{func} = '' unless defined $self->{func};
 440                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 441
 442                 # if there is any queued up broadcasts then splurge them out here
 443                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 444                         $self->send (@{$self->{delayed}});
 445                         delete $self->{delayed};
 446                 }
 447         }
 448         return $self->{state};
 449 }
 450
 451 # disconnect this channel
 452 sub disconnect
 453 {
 454         my $self = shift;
 455         my $user = $self->{user};
 456
 457         $user->close() if defined $user;
 458         $self->{conn}->disconnect;
 459         $self->del();
 460 }
 461
 462 #
 463 # just close all the socket connections down without any fiddling about, cleaning, being
 464 # nice to other processes and otherwise telling them what is going on.
 465 #
 466 # This is for the benefit of forked processes to prepare for starting new programs, they
 467 # don't want or need all this baggage.
 468 #
 469
 470 sub closeall
 471 {
 472         my $ref;
 473         foreach $ref (values %channels) {
 474                 $ref->{conn}->disconnect() if $ref->{conn};
 475         }
 476 }
 477
 478 #
 479 # Tell all the users that we have come in or out (if they want to know)
 480 #
 481 sub tell_login
 482 {
 483         my ($self, $m) = @_;
 484
 485         # send info to all logged in thingies
 486         my @dxchan = get_all_users();
 487         my $dxchan;
 488         foreach $dxchan (@dxchan) {
 489                 next if $dxchan == $self;
 490                 next if $dxchan->{call} eq $main::mycall;
 491                 $dxchan->send($dxchan->msg($m, $self->{call})) if $dxchan->{logininfo};
 492         }
 493 }
 494
 495 # various access routines
 496
 497 #
 498 # return a list of valid elements
 499 #
 500
 501 sub fields
 502 {
 503         return keys(%valid);
 504 }
 505
 506 #
 507 # return a prompt for a field
 508 #
 509
 510 sub field_prompt
 511 {
 512         my ($self, $ele) = @_;
 513         return $valid{$ele};
 514 }
 515
 516 # take a standard input message and decode it into its standard parts
 517 sub decode_input
 518 {
 519         my $dxchan = shift;
 520         my $data = shift;
 521         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 522
 523         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 524
 525         # the above regexp must work
 526         unless (defined $sort && defined $call && defined $line) {
 527 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 528                 dbg("DUFF Line on $chcall: $data");
 529                 return ();
 530         }
 531
 532         if(ref($dxchan) && $call ne $chcall) {
 533                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 534                 return();
 535         }
 536
 537         return ($sort, $call, $line);
 538 }
 539
 540 sub rspfcheck
 541 {
 542         my ($self, $flag, $node, $user) = @_;
 543         my $nref = Route::Node::get($node);
 544         my $dxchan = $nref->dxchan if $nref;
 545         if ($nref && $dxchan) {
 546             if ($dxchan == $self) {
 547                         return 1 unless $user;
 548                         return 1 if $user eq $node;
 549                         my @users = $nref->users;
 550                         return 1 if @users == 0 || grep $user eq $_, @users;
 551                         dbg("RSPF: $user not on $node") if isdbg('chanerr');
 552                 } else {
 553                         dbg("RSPF: Shortest path for $node is " . $nref->dxchan->{call}) if isdbg('chanerr');
 554                 }
 555         } else {
 556                 return 1 if $flag;
 557                 dbg("RSPF: required $node not found" ) if isdbg('chanerr');
 558         }
 559         return 0;
 560 }
 561
 562 # broadcast a message to all clusters taking into account isolation
 563 # [except those mentioned after buffer]
 564 sub broadcast_nodes
 565 {
 566         my $s = shift;                          # the line to be rebroadcast
 567         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 568         my @dxchan = get_all_nodes();
 569         my $dxchan;
 570
 571         # send it if it isn't the except list and isn't isolated and still has a hop count
 572         foreach $dxchan (@dxchan) {
 573                 next if grep $dxchan == $_, @except;
 574                 next if $dxchan == $main::me;
 575
 576                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 577
 578                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 579         }
 580 }
 581
 582 # broadcast a message to all clusters ignoring isolation
 583 # [except those mentioned after buffer]
 584 sub broadcast_all_nodes
 585 {
 586         my $s = shift;                          # the line to be rebroadcast
 587         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 588         my @dxchan = get_all_nodes();
 589         my $dxchan;
 590
 591         # send it if it isn't the except list and isn't isolated and still has a hop count
 592         foreach $dxchan (@dxchan) {
 593                 next if grep $dxchan == $_, @except;
 594                 next if $dxchan == $main::me;
 595
 596                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 597                 $dxchan->send($routeit);
 598         }
 599 }
 600
 601 # broadcast to all users
 602 # storing the spot or whatever until it is in a state to receive it
 603 sub broadcast_users
 604 {
 605         my $s = shift;                          # the line to be rebroadcast
 606         my $sort = shift;           # the type of transmission
 607         my $fref = shift;           # a reference to an object to filter on
 608         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 609         my @dxchan = get_all_users();
 610         my $dxchan;
 611         my @out;
 612
 613         foreach $dxchan (@dxchan) {
 614                 next if grep $dxchan == $_, @except;
 615                 push @out, $dxchan;
 616         }
 617         broadcast_list($s, $sort, $fref, @out);
 618 }
 619
 620
 621 # broadcast to a list of users
 622 sub broadcast_list
 623 {
 624         my $s = shift;
 625         my $sort = shift;
 626         my $fref = shift;
 627         my $dxchan;
 628
 629         foreach $dxchan (@_) {
 630                 my $filter = 1;
 631                 next if $dxchan == $main::me;
 632
 633                 if ($sort eq 'dx') {
 634                     next unless $dxchan->{dx};
 635                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 636                         next unless $filter;
 637                 }
 638                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 639                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 640                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 641                 next if $sort eq 'wx' && !$dxchan->{wx};
 642
 643                 $s =~ s/\a//og unless $dxchan->{beep};
 644
 645                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 646                         $dxchan->send($s);
 647                 } else {
 648                         $dxchan->delay($s);
 649                 }
 650         }
 651 }
 652
 653 sub process
 654 {
 655         foreach my $dxchan (get_all()) {
 656
 657                 while (my $data = shift @{$dxchan->{inqueue}}) {
 658                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 659                         next unless defined $sort;
 660
 661                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 662                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 663                         if ($dxchan->{disconnecting}) {
 664                                 dbg('In disconnection, ignored');
 665                                 next;
 666                         }
 667
 668                         # handle A records
 669                         my $user = $dxchan->user;
 670                         if ($sort eq 'A' || $sort eq 'O') {
 671                                 $dxchan->start($line, $sort);
 672                         } elsif ($sort eq 'I') {
 673                                 die "\$user not defined for $call" if !defined $user;
 674
 675                                 # normal input
 676                                 $dxchan->normal($line);
 677                         } elsif ($sort eq 'Z') {
 678                                 $dxchan->disconnect;
 679                         } elsif ($sort eq 'D') {
 680                                 ;                               # ignored (an echo)
 681                         } elsif ($sort eq 'G') {
 682                                 $dxchan->enhanced($line);
 683                         } else {
 684                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 685                         }
 686                 }
 687         }
 688 }
 689
 690 #no strict;
 691 sub AUTOLOAD
 692 {
 693         no strict;
 694         my $name = $AUTOLOAD;
 695         return if $name =~ /::DESTROY$/;
 696         $name =~ s/^.*:://o;
 697
 698         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 699
 700         # this clever line of code creates a subroutine which takes over from autoload
 701         # from OO Perl - Conway
 702         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 703         goto &$AUTOLOAD;
 704 }
 705
 706
 707 1;
 708 __END__;