perl/DXChannel.pm

   1 #
   2 # module to manage channel lists & data
   3 #
   4 # This is the base class for all channel operations, which is everything to do
   5 # with input and output really.
   6 #
   7 # The instance variable in the outside world will be generally be called $dxchan
   8 #
   9 # This class is 'inherited' (if that is the goobledegook for what I am doing)
  10 # by various other modules. The point to understand is that the 'instance variable'
  11 # is in fact what normal people would call the state vector and all useful info
  12 # about a connection goes in there.
  13 #
  14 # Another point to note is that a vector may contain a list of other vectors.
  15 # I have simply added another variable to the vector for 'simplicity' (or laziness
  16 # as it is more commonly called)
  17 #
  18 # PLEASE NOTE - I am a C programmer using this as a method of learning perl
  19 # firstly and OO about ninthly (if you don't like the design and you can't
  20 # improve it with better OO and thus make it smaller and more efficient, then tough).
  21 #
  22 # Copyright (c) 1998-2000 - Dirk Koopman G1TLH
  23 #
  24 #
  25 #
  26 package DXChannel;
  27
  28 use Msg;
  29 use DXM;
  30 use DXUtil;
  31 use DXVars;
  32 use DXDebug;
  33 use Filter;
  34 use Prefix;
  35 use Route;
  36
  37 use strict;
  38 use vars qw(%channels %valid @ISA $count $maxerrors);
  39
  40 %channels = ();
  41 $count = 0;
  42
  43 %valid = (
  44                   call => '0,Callsign',
  45                   conn => '9,Msg Conn ref',
  46                   user => '9,DXUser ref',
  47                   startt => '0,Start Time,atime',
  48                   t => '9,Time,atime',
  49                   pc50_t => '5,Last PC50 Time,atime',
  50                   priv => '9,Privilege',
  51                   state => '0,Current State',
  52                   oldstate => '5,Last State',
  53                   list => '9,Dep Chan List',
  54                   name => '0,User Name',
  55                   consort => '5,Connection Type',
  56                   'sort' => '5,Type of Channel',
  57                   wwv => '0,Want WWV,yesno',
  58                   wcy => '0,Want WCY,yesno',
  59                   wx => '0,Want WX,yesno',
  60                   talk => '0,Want Talk,yesno',
  61                   ann => '0,Want Announce,yesno',
  62                   here => '0,Here?,yesno',
  63                   conf => '0,In Conference?,yesno',
  64                   dx => '0,DX Spots,yesno',
  65                   redirect => '0,Redirect messages to',
  66                   lang => '0,Language',
  67                   func => '5,Function',
  68                   loc => '9,Local Vars', # used by func to store local variables in
  69                   beep => '0,Want Beeps,yesno',
  70                   lastread => '5,Last Msg Read',
  71                   outbound => '5,outbound?,yesno',
  72                   remotecmd => '9,doing rcmd,yesno',
  73                   pagelth => '0,Page Length',
  74                   pagedata => '9,Page Data Store',
  75                   group => '0,Access Group,parray',     # used to create a group of users/nodes for some purpose or other
  76                   isolate => '5,Isolate network,yesno',
  77                   delayed => '5,Delayed messages,parray',
  78                   annfilter => '5,Ann Filt-out',
  79                   wwvfilter => '5,WWV Filt-out',
  80                   wcyfilter => '5,WCY Filt-out',
  81                   spotsfilter => '5,Spot Filt-out',
  82                   routefilter => '5,Route Filt-out',
  83                   pc92filter => '5,PC92 Route Filt-out',
  84                   inannfilter => '5,Ann Filt-inp',
  85                   inwwvfilter => '5,WWV Filt-inp',
  86                   inwcyfilter => '5,WCY Filt-inp',
  87                   inspotsfilter => '5,Spot Filt-inp',
  88                   inroutefilter => '5,Route Filt-inp',
  89                   inpc92filter => '5,PC92 Route Filt-inp',
  90                   passwd => '9,Passwd List,yesno',
  91                   pingint => '5,Ping Interval ',
  92                   nopings => '5,Ping Obs Count',
  93                   lastping => '5,Ping last sent,atime',
  94                   pingtime => '5,Ping totaltime,parray',
  95                   pingave => '0,Ping ave time',
  96                   logininfo => '9,Login info req,yesno',
  97                   talklist => '0,Talk List,parray',
  98                   cluster => '5,Cluster data',
  99                   isbasic => '9,Internal Connection',
 100                   errors => '9,Errors',
 101                   route => '9,Route Data',
 102                   dxcc => '0,Country Code',
 103                   itu => '0,ITU Zone',
 104                   cq => '0,CQ Zone',
 105                   enhanced => '5,Enhanced Client,yesno',
 106                   gtk => '5,Using GTK,yesno',
 107                   senddbg => '8,Sending Debug,yesno',
 108                   width => '0,Column Width',
 109                   disconnecting => '9,Disconnecting,yesno',
 110                   ann_talk => '0,Suppress Talk Anns,yesno',
 111                   metric => '1,Route metric',
 112                   badcount => '1,Bad Word Count',
 113                   edit => '7,Edit Function',
 114                   registered => '9,Registered?,yesno',
 115                   prompt => '0,Required Prompt',
 116                   version => '1,Node Version',
 117                   build => '1,Node Build',
 118                   verified => '9,Verified?,yesno',
 119                   newroute => '1,New Style Routing,yesno',
 120                   ve7cc => '0,VE7CC program special,yesno',
 121                   lastmsgpoll => '0,Last Msg Poll,atime',
 122                   inscript => '9,In a script,yesno',
 123                   handle_xml => '9,Handles XML,yesno',
 124                   do_pc9x => '9,Handles PC9x,yesno',
 125                   inqueue => '9,Input Queue,parray',
 126                   next_pc92_update => '9,Next PC92 Update,atime',
 127                   next_pc92_keepalive => '9,Next PC92 KeepAlive,atime',
 128                   anyevents => '9,outstanding AnyEvent handles,parray',
 129                  );
 130
 131 $maxerrors = 20;                                # the maximum number of concurrent errors allowed before disconnection
 132
 133 # object destruction
 134 sub DESTROY
 135 {
 136         my $self = shift;
 137         for (keys %$self) {
 138                 if (ref($self->{$_})) {
 139                         delete $self->{$_};
 140                 }
 141         }
 142         dbg("DXChannel $self->{call} destroyed ($count)") if isdbg('chan');
 143         $count--;
 144 }
 145
 146 # create a new channel object [$obj = DXChannel->new($call, $msg_conn_obj, $user_obj)]
 147 sub alloc
 148 {
 149         my ($pkg, $call, $conn, $user) = @_;
 150         my $self = {};
 151
 152         die "trying to create a duplicate channel for $call" if $channels{$call};
 153         bless $self, $pkg;
 154
 155         $self->{call} = $call;
 156         $self->{priv} = 0;
 157         if (defined $conn && ref $conn) { # if this isn't defined then it must be a list
 158                 $self->{conn} = $conn;
 159                 $conn->set_on_eof(sub {$self->disconnect});
 160         }
 161         if (defined $user) {
 162                 $self->{user} = $user;
 163                 $self->{lang} = $user->lang;
 164                 $user->new_group unless $user->group;
 165                 $user->new_buddies unless $user->buddies;
 166                 $self->{group} = $user->group;
 167                 $self->{sort} = $user->sort;
 168         }
 169         $self->{startt} = $self->{t} = time;
 170         $self->{state} = 0;
 171         $self->{oldstate} = 0;
 172         $self->{lang} = $main::lang if !$self->{lang};
 173         $self->{func} = "";
 174
 175         # add in all the dxcc, itu, zone info
 176         my @dxcc = Prefix::extract($call);
 177         if (@dxcc > 0) {
 178                 $self->{dxcc} = $dxcc[1]->dxcc;
 179                 $self->{itu} = $dxcc[1]->itu;
 180                 $self->{cq} = $dxcc[1]->cq;
 181         }
 182         $self->{inqueue} = [];
 183         $self->{anyevents} = [];
 184
 185         $count++;
 186         dbg("DXChannel $self->{call} created ($count)") if isdbg('chan');
 187         return $channels{$call} = $self;
 188 }
 189
 190 # count errors and disconnect if too many
 191 # this has to be here because it can come from rcmd (DXProt) as
 192 # well as DXCommandmode.
 193 sub _error_out
 194 {
 195         my $self = shift;
 196         my $e = shift;
 197         if (++$self->{errors} > $maxerrors) {
 198                 $self->send($self->msg('e26'));
 199                 $self->disconnect;
 200                 return ();
 201         } else {
 202                 return ($self->msg($e));
 203         }
 204 }
 205
 206 # rebless this channel as something else
 207 sub rebless
 208 {
 209         my $self = shift;
 210         my $class = shift;
 211         my $new = bless $self, $class;
 212         $new->{conn}->on_eof(sub {$new->disconnect});
 213         return $channels{$self->{call}} = $new;
 214 }
 215
 216 sub rec
 217 {
 218         my ($self, $msg) = @_;
 219
 220         # queue the message and the channel object for later processing
 221         if (defined $msg) {
 222                 push @{$self->{inqueue}}, $msg;
 223         }
 224 }
 225
 226 # obtain a channel object by callsign [$obj = DXChannel::get($call)]
 227 sub get
 228 {
 229         my $call = shift;
 230         return $channels{$call};
 231 }
 232
 233 # obtain all the channel objects
 234 sub get_all
 235 {
 236         return values(%channels);
 237 }
 238
 239 #
 240 # gimme all the ak1a nodes
 241 #
 242 sub get_all_nodes
 243 {
 244         my $ref;
 245         my @out;
 246         foreach $ref (values %channels) {
 247                 push @out, $ref if $ref->is_node;
 248         }
 249         return @out;
 250 }
 251
 252 # return a list of node calls
 253 sub get_all_node_calls
 254 {
 255         my $ref;
 256         my @out;
 257         foreach $ref (values %channels) {
 258                 push @out, $ref->{call} if $ref->is_node;
 259         }
 260         return @out;
 261 }
 262
 263 # return a list of all users
 264 sub get_all_users
 265 {
 266         my $ref;
 267         my @out;
 268         foreach $ref (values %channels) {
 269                 push @out, $ref if $ref->is_user;
 270         }
 271         return @out;
 272 }
 273
 274 # return a list of all user callsigns
 275 sub get_all_user_calls
 276 {
 277         my $ref;
 278         my @out;
 279         foreach $ref (values %channels) {
 280                 push @out, $ref->{call} if $ref->is_user;
 281         }
 282         return @out;
 283 }
 284
 285 # obtain a channel object by searching for its connection reference
 286 sub get_by_cnum
 287 {
 288         my ($pkg, $conn) = @_;
 289         my $self;
 290
 291         foreach $self (values(%channels)) {
 292                 return $self if ($self->{conn} == $conn);
 293         }
 294         return undef;
 295 }
 296
 297 # get rid of a channel object [$obj->del()]
 298 sub del
 299 {
 300         my $self = shift;
 301
 302         $self->{group} = undef;         # belt and braces
 303         delete $channels{$self->{call}};
 304 }
 305
 306 # is it a bbs
 307 sub is_bbs
 308 {
 309         my $self = shift;
 310         return $self->{'sort'} eq 'B';
 311 }
 312
 313 sub is_node
 314 {
 315         my $self = shift;
 316         return $self->{'sort'} =~ /[ACRSXW]/;
 317 }
 318 # is it an ak1a node ?
 319 sub is_ak1a
 320 {
 321         my $self = shift;
 322         return $self->{'sort'} eq 'A';
 323 }
 324
 325 # is it a user?
 326 sub is_user
 327 {
 328         my $self = shift;
 329         return $self->{'sort'} eq 'U';
 330 }
 331
 332 # is it a clx node
 333 sub is_clx
 334 {
 335         my $self = shift;
 336         return $self->{'sort'} eq 'C';
 337 }
 338
 339 # it is Aranea
 340 sub is_aranea
 341 {
 342         my $self = shift;
 343         return $self->{'sort'} eq 'W';
 344 }
 345
 346 # is it a spider node
 347 sub is_spider
 348 {
 349         my $self = shift;
 350         return $self->{'sort'} eq 'S';
 351 }
 352
 353 # is it a DXNet node
 354 sub is_dxnet
 355 {
 356         my $self = shift;
 357         return $self->{'sort'} eq 'X';
 358 }
 359
 360 # is it a ar-cluster node
 361 sub is_arcluster
 362 {
 363         my $self = shift;
 364         return $self->{'sort'} eq 'R';
 365 }
 366
 367 # for perl 5.004's benefit
 368 sub sort
 369 {
 370         my $self = shift;
 371         return @_ ? $self->{'sort'} = shift : $self->{'sort'} ;
 372 }
 373
 374 # find out whether we are prepared to believe this callsign on this interface
 375 sub is_believed
 376 {
 377         my $self = shift;
 378         my $call = shift;
 379
 380         return grep $call eq $_, $self->user->believe;
 381 }
 382
 383 # handle out going messages, immediately without waiting for the select to drop
 384 # this could, in theory, block
 385 sub send_now
 386 {
 387         my $self = shift;
 388         my $conn = $self->{conn};
 389         return unless $conn;
 390         my $sort = shift;
 391         my $call = $self->{call};
 392
 393         for (@_) {
 394 #               chomp;
 395         my @lines = split /\n/;
 396                 for (@lines) {
 397                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 398                         $conn->send_now("$sort$call|$_");
 399                         # debug log it, but not if it is a log message
 400                 }
 401         }
 402         $self->{t} = time;
 403 }
 404
 405 #
 406 # send later with letter (more control)
 407 #
 408
 409 sub send_later
 410 {
 411         my $self = shift;
 412         my $conn = $self->{conn};
 413         return unless $conn;
 414         my $sort = shift;
 415         my $call = $self->{call};
 416
 417         for (@_) {
 418 #               chomp;
 419         my @lines = split /\n/;
 420                 for (@lines) {
 421                         dbg("-> $sort $call $_") if $sort ne 'L' && isdbg('chan');
 422                         $conn->send_later("$sort$call|$_");
 423                         # debug log it, but not if it is a log message
 424                 }
 425         }
 426         $self->{t} = time;
 427 }
 428
 429 #
 430 # the normal output routine
 431 #
 432 sub send                                                # this is always later and always data
 433 {
 434         my $self = shift;
 435         my $conn = $self->{conn};
 436         return unless $conn;
 437         my $call = $self->{call};
 438
 439         foreach my $l (@_) {
 440                 for (ref $l ? @$l : $l) {
 441                         my @lines = split /\n/;
 442                         for (@lines) {
 443                                 dbg("-> D $call $_") if isdbg('chan');
 444                                 $conn->send_later("D$call|$_");
 445                         }
 446                 }
 447         }
 448         $self->{t} = $main::systime;
 449 }
 450
 451 # send a file (always later)
 452 sub send_file
 453 {
 454         my ($self, $fn) = @_;
 455         my $call = $self->{call};
 456         my $conn = $self->{conn};
 457         my @buf;
 458
 459         open(F, $fn) or die "can't open $fn for sending file ($!)";
 460         @buf = <F>;
 461         close(F);
 462         $self->send(@buf);
 463 }
 464
 465 # this will implement language independence (in time)
 466 sub msg
 467 {
 468         my $self = shift;
 469         return DXM::msg($self->{lang}, @_);
 470 }
 471
 472 # stick a broadcast on the delayed queue (but only up to 20 items)
 473 sub delay
 474 {
 475         my $self = shift;
 476         my $s = shift;
 477
 478         $self->{delayed} = [] unless $self->{delayed};
 479         push @{$self->{delayed}}, $s;
 480         if (@{$self->{delayed}} >= 20) {
 481                 shift @{$self->{delayed}};   # lose oldest one
 482         }
 483 }
 484
 485 # change the state of the channel - lots of scope for debugging here :-)
 486 sub state
 487 {
 488         my $self = shift;
 489         if (@_) {
 490                 $self->{oldstate} = $self->{state};
 491                 $self->{state} = shift;
 492                 $self->{func} = '' unless defined $self->{func};
 493                 dbg("$self->{call} channel func $self->{func} state $self->{oldstate} -> $self->{state}\n") if isdbg('state');
 494
 495                 # if there is any queued up broadcasts then splurge them out here
 496                 if ($self->{delayed} && ($self->{state} eq 'prompt' || $self->{state} eq 'talk')) {
 497                         $self->send (@{$self->{delayed}});
 498                         delete $self->{delayed};
 499                 }
 500         }
 501         return $self->{state};
 502 }
 503
 504 # disconnect this channel
 505 sub disconnect
 506 {
 507         my $self = shift;
 508         my $user = $self->{user};
 509
 510         $user->close() if defined $user;
 511         $self->{conn}->close_on_empty if $self->{conn};
 512         $self->del();
 513 }
 514
 515 #
 516 # just close all the socket connections down without any fiddling about, cleaning, being
 517 # nice to other processes and otherwise telling them what is going on.
 518 #
 519 # This is for the benefit of forked processes to prepare for starting new programs, they
 520 # don't want or need all this baggage.
 521 #
 522
 523 sub closeall
 524 {
 525         my $ref;
 526         foreach $ref (values %channels) {
 527                 $ref->{conn}->disconnect() if $ref->{conn};
 528         }
 529 }
 530
 531 #
 532 # Tell all the users that we have come in or out (if they want to know)
 533 #
 534 sub tell_login
 535 {
 536         my ($self, $m, $call) = @_;
 537
 538         $call ||= $self->{call};
 539
 540         # send info to all logged in thingies
 541         my @dxchan = get_all_users();
 542         my $dxchan;
 543         foreach $dxchan (@dxchan) {
 544                 next if $dxchan == $self;
 545                 next if $dxchan->{call} eq $main::mycall;
 546                 $dxchan->send($dxchan->msg($m, $call)) if $dxchan->{logininfo};
 547         }
 548 }
 549
 550 #
 551 # Tell all the users if a buddy is logged or out
 552 #
 553 sub tell_buddies
 554 {
 555         my ($self, $m, $call, $node) = @_;
 556
 557         $call ||= $self->{call};
 558         $call =~ s/-\d+$//;
 559         $m .= 'n' if $node;
 560
 561         # send info to all logged in thingies
 562         my @dxchan = get_all_users();
 563         my $dxchan;
 564         foreach $dxchan (@dxchan) {
 565                 next if $dxchan == $self;
 566                 next if $dxchan->{call} eq $main::mycall;
 567                 $dxchan->send($dxchan->msg($m, $call, $node)) if grep $_ eq $call, @{$dxchan->{user}->{buddies}} ;
 568         }
 569 }
 570
 571 # various access routines
 572
 573 #
 574 # return a list of valid elements
 575 #
 576
 577 sub fields
 578 {
 579         return keys(%valid);
 580 }
 581
 582 #
 583 # return a prompt for a field
 584 #
 585
 586 sub field_prompt
 587 {
 588         my ($self, $ele) = @_;
 589         return $valid{$ele};
 590 }
 591
 592 # take a standard input message and decode it into its standard parts
 593 sub decode_input
 594 {
 595         my $dxchan = shift;
 596         my $data = shift;
 597         my ($sort, $call, $line) = $data =~ /^([A-Z])([A-Z0-9\-]{3,9})\|(.*)$/;
 598
 599         my $chcall = (ref $dxchan) ? $dxchan->call : "UN.KNOWN";
 600
 601         # the above regexp must work
 602         unless (defined $sort && defined $call && defined $line) {
 603 #               $data =~ s/([\x00-\x1f\x7f-\xff])/uc sprintf("%%%02x",ord($1))/eg;
 604                 dbg("DUFF Line on $chcall: $data");
 605                 return ();
 606         }
 607
 608         if(ref($dxchan) && $call ne $chcall) {
 609                 dbg("DUFF Line come in for $call on wrong channel $chcall");
 610                 return();
 611         }
 612
 613         return ($sort, $call, $line);
 614 }
 615
 616 # broadcast a message to all clusters taking into account isolation
 617 # [except those mentioned after buffer]
 618 sub broadcast_nodes
 619 {
 620         my $s = shift;                          # the line to be rebroadcast
 621         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 622         my @dxchan = get_all_nodes();
 623         my $dxchan;
 624
 625         # send it if it isn't the except list and isn't isolated and still has a hop count
 626         foreach $dxchan (@dxchan) {
 627                 next if grep $dxchan == $_, @except;
 628                 next if $dxchan == $main::me;
 629
 630                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 631
 632                 $dxchan->send($routeit) unless $dxchan->{isolate} || !$routeit;
 633         }
 634 }
 635
 636 # broadcast a message to all clusters ignoring isolation
 637 # [except those mentioned after buffer]
 638 sub broadcast_all_nodes
 639 {
 640         my $s = shift;                          # the line to be rebroadcast
 641         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 642         my @dxchan = get_all_nodes();
 643         my $dxchan;
 644
 645         # send it if it isn't the except list and isn't isolated and still has a hop count
 646         foreach $dxchan (@dxchan) {
 647                 next if grep $dxchan == $_, @except;
 648                 next if $dxchan == $main::me;
 649
 650                 my $routeit = $dxchan->can('adjust_hops') ? $dxchan->adjust_hops($s) : $s;      # adjust its hop count by node name
 651                 $dxchan->send($routeit);
 652         }
 653 }
 654
 655 # broadcast to all users
 656 # storing the spot or whatever until it is in a state to receive it
 657 sub broadcast_users
 658 {
 659         my $s = shift;                          # the line to be rebroadcast
 660         my $sort = shift;           # the type of transmission
 661         my $fref = shift;           # a reference to an object to filter on
 662         my @except = @_;                        # to all channels EXCEPT these (dxchannel refs)
 663         my @dxchan = get_all_users();
 664         my $dxchan;
 665         my @out;
 666
 667         foreach $dxchan (@dxchan) {
 668                 next if grep $dxchan == $_, @except;
 669                 push @out, $dxchan;
 670         }
 671         broadcast_list($s, $sort, $fref, @out);
 672 }
 673
 674
 675 # broadcast to a list of users
 676 sub broadcast_list
 677 {
 678         my $s = shift;
 679         my $sort = shift;
 680         my $fref = shift;
 681         my $dxchan;
 682
 683         foreach $dxchan (@_) {
 684                 my $filter = 1;
 685                 next if $dxchan == $main::me;
 686
 687                 if ($sort eq 'dx') {
 688                     next unless $dxchan->{dx};
 689                         ($filter) = $dxchan->{spotsfilter}->it(@{$fref}) if ref $fref;
 690                         next unless $filter;
 691                 }
 692                 next if $sort eq 'ann' && !$dxchan->{ann} && $s !~ /^To\s+LOCAL\s+de\s+(?:$main::myalias|$main::mycall)/i;
 693                 next if $sort eq 'wwv' && !$dxchan->{wwv};
 694                 next if $sort eq 'wcy' && !$dxchan->{wcy};
 695                 next if $sort eq 'wx' && !$dxchan->{wx};
 696
 697                 $s =~ s/\a//og unless $dxchan->{beep};
 698
 699                 if ($dxchan->{state} eq 'prompt' || $dxchan->{state} eq 'talk') {
 700                         $dxchan->send($s);
 701                 } else {
 702                         $dxchan->delay($s);
 703                 }
 704         }
 705 }
 706
 707 sub process
 708 {
 709         foreach my $dxchan (values %channels) {
 710
 711                 next if $dxchan->{disconnecting};
 712
 713                 while (my $data = shift @{$dxchan->{inqueue}}) {
 714                         my ($sort, $call, $line) = $dxchan->decode_input($data);
 715                         next unless defined $sort;
 716
 717                         # do the really sexy console interface bit! (Who is going to do the TK interface then?)
 718                         dbg("<- $sort $call $line") if $sort ne 'D' && isdbg('chan');
 719
 720                         # handle A records
 721                         my $user = $dxchan->user;
 722                         if ($sort eq 'A' || $sort eq 'O') {
 723                                 $dxchan->start($line, $sort);
 724                         } elsif ($sort eq 'I') {
 725                                 die "\$user not defined for $call" if !defined $user;
 726
 727                                 # normal input
 728                                 $dxchan->normal($line);
 729                         } elsif ($sort eq 'Z') {
 730                                 $dxchan->disconnect;
 731                         } elsif ($sort eq 'D') {
 732                                 ;                               # ignored (an echo)
 733                         } elsif ($sort eq 'G') {
 734                                 $dxchan->enhanced($line);
 735                         } else {
 736                                 print STDERR atime, " Unknown command letter ($sort) received from $call\n";
 737                         }
 738                 }
 739         }
 740 }
 741
 742 sub handle_xml
 743 {
 744         my $self = shift;
 745         my $r = 0;
 746
 747         if (DXXml::available()) {
 748                 $r = $self->{handle_xml} || 0;
 749         } else {
 750                 delete $self->{handle_xml} if exists $self->{handle_xml};
 751         }
 752         return $r;
 753 }
 754
 755 sub anyevent_add
 756 {
 757         my $self = shift;
 758         my $handle = shift;
 759         my $sort = shift || "unknown";
 760
 761         push @{$self->{anyevents}}, $handle;
 762         dbg("anyevent: add $sort handle making " . scalar @{$self->{anyevents}} . " handles in use") if isdbg('anyevent');
 763 }
 764
 765 sub anyevent_del
 766 {
 767         my $self = shift;
 768         my $handle = shift;
 769         my $sort = shift || "unknown";
 770         $self->{anyevents} = [ grep {$_ != $handle} @{$self->{anyevents}} ];
 771         dbg("anyevent: delete $sort handle making " . scalar @{$self->{anyevents}} . " handles in use") if isdbg('anyevent');
 772 }
 773
 774 #no strict;
 775 sub AUTOLOAD
 776 {
 777         no strict;
 778         my $name = $AUTOLOAD;
 779         return if $name =~ /::DESTROY$/;
 780         $name =~ s/^.*:://o;
 781
 782         confess "Non-existant field '$AUTOLOAD'" if !$valid{$name};
 783
 784         # this clever line of code creates a subroutine which takes over from autoload
 785         # from OO Perl - Conway
 786         *$AUTOLOAD = sub {@_ > 1 ? $_[0]->{$name} = $_[1] : $_[0]->{$name}};
 787         goto &$AUTOLOAD;
 788 }
 789
 790
 791 1;
 792 __END__;